blob: ec3f21c69d154bbcc1096aec38dea36c4d2ea42e (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
{ lib, stdenv, fetchFromGitHub, makeWrapper, coreutils, findutils, getopt, gnugrep, gnused, sops, vault }:
stdenv.mkDerivation rec {
pname = "helm-secrets";
version = "3.8.1";
src = fetchFromGitHub {
owner = "jkroepke";
repo = pname;
rev = "v${version}";
hash = "sha256-UZu3jChEK59UrtUR2ze68Kkc6MkHRtTsfTOS/B96sLM=";
};
nativeBuildInputs = [ makeWrapper ];
buildInputs = [ getopt sops ];
# NOTE: helm-secrets is comprised of shell scripts.
dontBuild = true;
# NOTE: Remove the install and upgrade hooks.
postPatch = ''
sed -i '/^hooks:/,+2 d' plugin.yaml
'';
installPhase = ''
runHook preInstall
install -dm755 $out/${pname} $out/${pname}/scripts
install -m644 -Dt $out/${pname} plugin.yaml
cp -r scripts/* $out/${pname}/scripts
wrapProgram $out/${pname}/scripts/run.sh \
--prefix PATH : ${lib.makeBinPath [ coreutils findutils getopt gnugrep gnused sops vault ]}
runHook postInstall
'';
meta = with lib; {
description = "A Helm plugin that helps manage secrets";
inherit (src.meta) homepage;
license = licenses.apsl20;
maintainers = with maintainers; [ yurrriq ];
platforms = platforms.all;
};
}
|