blob: 70cb33643ee6705cbae720a896e52287f1854601 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
|
{ stdenv
, lib
, fetchpatch
, fetchFromGitHub
, python3
, qtbase
, qttools
, git-lfs
, wrapQtAppsHook
}:
let
pydeps = with python3.pkgs; [
numpy
pyqt5
pyopengl
];
python = python3.withPackages (pkgs: pydeps);
in
stdenv.mkDerivation rec {
pname = "makehuman";
version = "1.2.0";
source = fetchFromGitHub {
owner = "makehumancommunity";
repo = "makehuman";
rev = "v${version}";
hash = "sha256-mCv6H0B7b4uxozpNHkKsG+Is2H0QYEJnnzKCHixhBpY=";
name = "${pname}-source";
};
assets = fetchFromGitHub {
owner = "makehumancommunity";
repo = "makehuman-assets";
rev = "v${version}";
hash = "sha256-Jd2A0PAHVdFMnDLq4Mu5wsK/E6A4QpKjUyv66ix1Gbo=";
name = "${pname}-assets-source";
};
patches = [
# work with numpy>=1.24
(fetchpatch {
name = "fix-compile_targets.py-when-using-numpy-1.24.0-or-newer";
url = "https://patch-diff.githubusercontent.com/raw/makehumancommunity/makehuman/pull/220.patch";
hash = "sha256-ip7U83cCBrl+4gM1GZ2QQIER5Qur6HRu3a/TnHqk//g=";
})
# crash related to collections.Callable -> collections.abc.Callable
(fetchpatch {
name = "remove-unnecessary-compatibility-test";
url = "https://patch-diff.githubusercontent.com/raw/makehumancommunity/makehuman/pull/188.patch";
hash = "sha256-HGrk3n7rhV4YgK8mNUdfHwQl8dFT8yuzjxorvwfMmJw=";
})
# some OpenGL issue causing blank windows on recent Qt
(fetchpatch {
name = "qt-opengl-update-from-qglwidget-to-qopenglwidget-to-fix-blank";
url = "https://patch-diff.githubusercontent.com/raw/makehumancommunity/makehuman/pull/197.patch";
hash = "sha256-fEqBwg1Jd36nKWIT9XPr6Buj1N3AmTQg2LBaoX3eTxw=";
})
# multisampling issue
(fetchpatch {
name = "switch-default-for-multisampling-and-disable-sample-buffers";
url = "https://github.com/makehumancommunity/makehuman/commit/c47b884028a24eb190d097e7523a3059e439cb6f.patch";
hash = "sha256-tknQHX9qQYH15gyOLNhxfO3bsFVIv3Z1F7ZXD1IT1h4=";
})
# PyQt >= 5.12
(fetchpatch {
name = "fix-scrolling-issue-on-pyqt5>=5.12";
url = "https://github.com/makehumancommunity/makehuman/commit/02c4269a2d4c57f68159fe8f437a8b1978b99099.patch";
hash = "sha256-yR5tZcELX0N83PW/vS6yB5xKoZcHhVp48invlu7quWM=";
})
];
srcs = [
source
assets
];
sourceRoot = ".";
nativeBuildInputs = [
python
qtbase
git-lfs
wrapQtAppsHook
];
buildInputs = [
python
qtbase
];
propagatedBuildInputs = with python3.pkgs; [
pydeps
];
finalSource = "${pname}-final";
postUnpack = ''
mkdir -p $finalSource
cp -r $source/makehuman $finalSource
chmod u+w $finalSource --recursive
cp -r $assets/base/* $finalSource/makehuman/data
chmod u+w $finalSource --recursive
sourceRoot=$finalSource
'';
configurePhase = ''
runHook preConfigure
pushd ./makehuman
bash ./cleannpz.sh
bash ./cleanpyc.sh
python3 ./compile_targets.py
python3 ./compile_models.py
python3 ./compile_proxies.py
popd
runHook postConfigure
'';
buildPhase = ''
runHook preBuild
mkdir -p $out/opt $out/bin
cp -r * $out/opt
python -m compileall -o 0 -o 2 $out/opt
ln -s $out/opt/makehuman/makehuman.py $out/bin/makehuman
chmod +x $out/bin/makehuman
runHook postBuild
'';
preFixup = ''
wrapQtApp $out/bin/makehuman
'';
meta = {
description = "Software to create realistic humans";
homepage = "http://www.makehumancommunity.org/";
license = with lib.licenses; [ agpl3Plus cc0 ];
longDescription = ''
MakeHuman is a GUI program for procedurally generating
realistic-looking humans.
'';
mainProgram = "makehuman";
maintainers = with lib.maintainers; [ elisesouche ];
platforms = lib.platforms.all;
};
}
|