nixpkgs/pkgs/applications/graphics/upscayl/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

{
  appimageTools,
  fetchurl,
  lib,
}: let
  pname = "upscayl";
  version = "2.9.9";

  src = fetchurl {
    url = "https://github.com/upscayl/upscayl/releases/download/v${version}/upscayl-${version}-linux.AppImage";
    hash = "sha256-EoTFvlLsXQYZldXfEHhP3/bHygm+NdeDsf+p138mM8w";
  };

  appimageContents = appimageTools.extractType2 {
    inherit pname version src;
  };
in
  appimageTools.wrapType2 {
    inherit pname version src;

    extraPkgs = pkgs: with pkgs; [vulkan-headers vulkan-loader];

    extraInstallCommands = ''
      mkdir -p $out/share/{applications,pixmaps}

      cp ${appimageContents}/${pname}.desktop $out/share/applications/${pname}.desktop
      cp ${appimageContents}/${pname}.png $out/share/pixmaps/${pname}.png

      mv $out/bin/${pname}-${version} $out/bin/${pname}

      substituteInPlace $out/share/applications/${pname}.desktop \
        --replace 'Exec=AppRun --no-sandbox %U' 'Exec=${pname}'
    '';

    meta = with lib; {
      description = "Free and Open Source AI Image Upscaler";
      homepage = "https://upscayl.github.io/";
      maintainers = with maintainers; [icy-thought];
      license = licenses.agpl3Plus;
      platforms = platforms.linux;
      mainProgram = "upscayl";
    };
  }