blob: bca06406eba95fff550370b7241ca609436882af (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
{ lib
, rustPlatform
, fetchFromGitHub
, stdenv
, installShellFiles
, pkg-config
, openssl
, python3
, libxcb
, AppKit
, Security
}:
rustPlatform.buildRustPackage rec {
pname = "spotify-tui";
version = "0.25.0";
src = fetchFromGitHub {
owner = "Rigellute";
repo = "spotify-tui";
rev = "v${version}";
hash = "sha256-L5gg6tjQuYoAC89XfKE38KCFONwSAwfNoFEUPH4jNAI=";
};
cargoLock = {
lockFile = ./Cargo.lock;
};
nativeBuildInputs = [ installShellFiles ] ++ lib.optionals stdenv.isLinux [ pkg-config python3 ];
buildInputs = [ ]
++ lib.optionals stdenv.isLinux [ openssl libxcb ]
++ lib.optionals stdenv.isDarwin [ AppKit Security ];
postPatch = ''
# update Cargo.lock to fix build
ln -sf ${./Cargo.lock} Cargo.lock
# Add patch adding the collection variant to rspotify used by spotify-tu
# This fixes the issue of getting an error when playing liked songs
# see https://github.com/NixOS/nixpkgs/pull/170915
patch -p1 -d $cargoDepsCopy/rspotify-0.10.0 < ${./0001-Add-Collection-SearchType.patch}
'';
postInstall = ''
for shell in bash fish zsh; do
$out/bin/spt --completions $shell > spt.$shell
installShellCompletion spt.$shell
done
'';
meta = with lib; {
description = "Spotify for the terminal written in Rust";
homepage = "https://github.com/Rigellute/spotify-tui";
changelog = "https://github.com/Rigellute/spotify-tui/blob/v${version}/CHANGELOG.md";
license = with licenses; [ mit /* or */ asl20 ];
maintainers = with maintainers; [ jwijenbergh ];
mainProgram = "spt";
};
}
|