blob: 50ad72dc7388d4834411a36ea8cfe0e9db6b82f6 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
{ config, lib, pkgs, utils, ... }:
with lib;
let
xcfg = config.services.xserver;
cfg = xcfg.desktopManager.lxqt;
in
{
meta = {
maintainers = teams.lxqt.members;
};
options = {
services.xserver.desktopManager.lxqt.enable = mkOption {
type = types.bool;
default = false;
description = lib.mdDoc "Enable the LXQt desktop manager";
};
environment.lxqt.excludePackages = mkOption {
default = [];
example = literalExpression "[ pkgs.lxqt.qterminal ]";
type = types.listOf types.package;
description = lib.mdDoc "Which LXQt packages to exclude from the default environment";
};
};
config = mkIf cfg.enable {
services.xserver.desktopManager.session = singleton {
name = "lxqt";
bgSupport = true;
start = ''
# Upstream installs default configuration files in
# $prefix/share/lxqt instead of $prefix/etc/xdg, (arguably)
# giving distributors freedom to ship custom default
# configuration files more easily. In order to let the session
# manager find them the share subdirectory is added to the
# XDG_CONFIG_DIRS environment variable.
#
# For an explanation see
# https://github.com/lxqt/lxqt/issues/1521#issuecomment-405097453
#
export XDG_CONFIG_DIRS=$XDG_CONFIG_DIRS''${XDG_CONFIG_DIRS:+:}${config.system.path}/share
exec ${pkgs.lxqt.lxqt-session}/bin/startlxqt
'';
};
environment.systemPackages =
pkgs.lxqt.preRequisitePackages ++
pkgs.lxqt.corePackages ++
(utils.removePackagesByName
pkgs.lxqt.optionalPackages
config.environment.lxqt.excludePackages);
# Link some extra directories in /run/current-system/software/share
environment.pathsToLink = [ "/share" ];
# virtual file systems support for PCManFM-QT
services.gvfs.enable = true;
services.upower.enable = config.powerManagement.enable;
services.xserver.libinput.enable = mkDefault true;
xdg.portal.lxqt.enable = true;
# https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=1050804
xdg.portal.config.lxqt.default = mkDefault [ "lxqt" "gtk" ];
};
}
|