blob: a47ee0773d1792a2e13aaeaaaa6bfac579485fcb (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
|
{ config, lib, options, pkgs, ... }:
with lib;
let
cfg = config.services.ntopng;
opt = options.services.ntopng;
createRedis = cfg.redis.createInstance != null;
redisService =
if cfg.redis.createInstance == "" then
"redis.service"
else
"redis-${cfg.redis.createInstance}.service";
configFile = if cfg.configText != "" then
pkgs.writeText "ntopng.conf" ''
${cfg.configText}
''
else
pkgs.writeText "ntopng.conf" ''
${concatStringsSep "\n" (map (e: "--interface=${e}") cfg.interfaces)}
--http-port=${toString cfg.httpPort}
--redis=${cfg.redis.address}
--data-dir=/var/lib/ntopng
--user=ntopng
${cfg.extraConfig}
'';
in
{
imports = [
(mkRenamedOptionModule [ "services" "ntopng" "http-port" ] [ "services" "ntopng" "httpPort" ])
];
options = {
services.ntopng = {
enable = mkOption {
default = false;
type = types.bool;
description = lib.mdDoc ''
Enable ntopng, a high-speed web-based traffic analysis and flow
collection tool.
With the default configuration, ntopng monitors all network
interfaces and displays its findings at http://localhost:''${toString
config.${opt.http-port}}. Default username and password is admin/admin.
See the ntopng(8) manual page and http://www.ntop.org/products/ntop/
for more info.
Note that enabling ntopng will also enable redis (key-value
database server) for persistent data storage.
'';
};
interfaces = mkOption {
default = [ "any" ];
example = [ "eth0" "wlan0" ];
type = types.listOf types.str;
description = lib.mdDoc ''
List of interfaces to monitor. Use "any" to monitor all interfaces.
'';
};
httpPort = mkOption {
default = 3000;
type = types.int;
description = lib.mdDoc ''
Sets the HTTP port of the embedded web server.
'';
};
redis.address = mkOption {
type = types.str;
example = literalExpression "config.services.redis.ntopng.unixSocket";
description = lib.mdDoc ''
Redis address - may be a Unix socket or a network host and port.
'';
};
redis.createInstance = mkOption {
type = types.nullOr types.str;
default = optionalString (versionAtLeast config.system.stateVersion "22.05") "ntopng";
description = lib.mdDoc ''
Local Redis instance name. Set to `null` to disable
local Redis instance. Defaults to `""` for
`system.stateVersion` older than 22.05.
'';
};
configText = mkOption {
default = "";
example = ''
--interface=any
--http-port=3000
--disable-login
'';
type = types.lines;
description = lib.mdDoc ''
Overridable configuration file contents to use for ntopng. By
default, use the contents automatically generated by NixOS.
'';
};
extraConfig = mkOption {
default = "";
type = types.lines;
description = lib.mdDoc ''
Configuration lines that will be appended to the generated ntopng
configuration file. Note that this mechanism does not work when the
manual {option}`configText` option is used.
'';
};
};
};
config = mkIf cfg.enable {
# ntopng uses redis for data storage
services.ntopng.redis.address =
mkIf createRedis config.services.redis.servers.${cfg.redis.createInstance}.unixSocket;
services.redis.servers = mkIf createRedis {
${cfg.redis.createInstance} = {
enable = true;
user = mkIf (cfg.redis.createInstance == "ntopng") "ntopng";
};
};
# nice to have manual page and ntopng command in PATH
environment.systemPackages = [ pkgs.ntopng ];
systemd.tmpfiles.rules = [ "d /var/lib/ntopng 0700 ntopng ntopng -" ];
systemd.services.ntopng = {
description = "Ntopng Network Monitor";
requires = optional createRedis redisService;
after = [ "network.target" ] ++ optional createRedis redisService;
wantedBy = [ "multi-user.target" ];
serviceConfig.ExecStart = "${pkgs.ntopng}/bin/ntopng ${configFile}";
unitConfig.Documentation = "man:ntopng(8)";
};
users.extraUsers.ntopng = {
group = "ntopng";
isSystemUser = true;
};
users.extraGroups.ntopng = { };
};
}
|