nixpkgs/nixos/modules/services/monitoring/prometheus/exporters/kea.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

{ config
, lib
, pkgs
, utils
, ...
}:

with lib;

let
  cfg = config.services.prometheus.exporters.kea;
in {
  imports = [
    (mkRenamedOptionModule [ "controlSocketPaths" ] [ "targets" ])
  ];
  port = 9547;
  extraOpts = {
    targets = mkOption {
      type = types.listOf types.str;
      example = literalExpression ''
        [
          "/run/kea/kea-dhcp4.socket"
          "/run/kea/kea-dhcp6.socket"
          "http://127.0.0.1:8547"
        ]
      '';
      description = lib.mdDoc ''
        Paths or URLs to the Kea control socket.
      '';
    };
  };
  serviceOpts = {
    after = [
      "kea-dhcp4-server.service"
      "kea-dhcp6-server.service"
    ];
    serviceConfig = {
      User = "kea";
      DynamicUser = true;
      ExecStart = utils.escapeSystemdExecArgs ([
        (lib.getExe pkgs.prometheus-kea-exporter)
        "--address" cfg.listenAddress
        "--port" cfg.port
      ] ++ cfg.extraFlags ++ cfg.targets);
      RuntimeDirectory = "kea";
      RuntimeDirectoryPreserve = true;
      RestrictAddressFamilies = [
        # Need AF_UNIX to collect data
        "AF_UNIX"
      ];
    };
  };
}