nixpkgs/nixos/modules/config/xdg/portals/lxqt.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

{ config, pkgs, lib, ... }:

with lib;

let
  cfg = config.xdg.portal.lxqt;

in
{
  meta = {
    maintainers = teams.lxqt.members;
  };

  options.xdg.portal.lxqt = {
    enable = mkEnableOption ''
      the desktop portal for the LXQt desktop environment.

      This will add the <package>lxqt.xdg-desktop-portal-lxqt</package>
      package (with the extra Qt styles) into the
      <option>xdg.portal.extraPortals</option> option
    '';

    styles = mkOption {
      type = types.listOf types.package;
      default = [];
      example = literalExpression ''[
        pkgs.libsForQt5.qtstyleplugin-kvantum
        pkgs.breeze-qt5
        pkgs.qtcurve
      ];
      '';
      description = ''
        Extra Qt styles that will be available to the
        <package>lxqt.xdg-desktop-portal-lxqt</package>.
      '';
    };
  };

  config = mkIf cfg.enable {
    xdg.portal = {
      enable = true;
      extraPortals = [
        (pkgs.lxqt.xdg-desktop-portal-lxqt.override { extraQtStyles = cfg.styles; })
      ];
    };

    environment.systemPackages = cfg.styles;
  };
}