nixpkgs/nixos/modules/config/fonts/packages.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

{ config, lib, pkgs, ... }:

let
  cfg = config.fonts;
in
{
  imports = [
    (lib.mkRemovedOptionModule [ "fonts" "enableCoreFonts" ] "Use fonts.packages = [ pkgs.corefonts ]; instead.")
    (lib.mkRenamedOptionModule [ "fonts" "enableDefaultFonts" ] [ "fonts" "enableDefaultPackages" ])
    (lib.mkRenamedOptionModule [ "fonts" "fonts" ] [ "fonts" "packages" ])
  ];

  options = {
    fonts = {
      packages = lib.mkOption {
        type = with lib.types; listOf path;
        default = [];
        example = lib.literalExpression "[ pkgs.dejavu_fonts ]";
        description = lib.mdDoc "List of primary font packages.";
      };

      enableDefaultPackages = lib.mkOption {
        type = lib.types.bool;
        default = false;
        description = lib.mdDoc ''
          Enable a basic set of fonts providing several styles
          and families and reasonable coverage of Unicode.
        '';
      };
    };
  };

  config = {
    fonts.packages = lib.mkIf cfg.enableDefaultPackages (with pkgs; [
      dejavu_fonts
      freefont_ttf
      gyre-fonts # TrueType substitutes for standard PostScript fonts
      liberation_ttf
      unifont
      noto-fonts-color-emoji
    ]);
  };
}