modules/server/spectrum/patch-refs/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

{ lib, pkgs, ... }:

{
  users.users.patch-refs = {
    description = "spectrum-devel patch monitor";
    group = "spectrum";
    isSystemUser = true;
  };

  services.postfix.virtual = ''
    patch-refs@spectrum-os.org patch-refs@spectrum-os.org
  '';

  services.postfix.transport = ''
    patch-refs@spectrum-os.org patch-refs:
  '';

  services.postfix.masterConfig.patch-refs = {
    type = "unix";
    command = "pipe";
    privileged = true;
    args = [
      "flags=X"
      "user=patch-refs"
      "argv=${with pkgs; toString [
        "${execline}/bin/export" "PATH"
        (lib.makeBinPath [
          b4 coreutils findutils gitMinimal strace

          (mblaze.overrideAttrs ({ patches ? [], ... }: {
            patches = patches ++ [
              (fetchpatch {
                url = "https://inbox.vuxu.org/mblaze/20220523170921.2623516-1-hi@alyssa.is/raw";
                sha256 = "1fwnr6277fjdrv0lvjrzyxjd1p94c6jg2nl6cd4lh9aizmfbjiq0";
              })
            ];
          }))
        ])
        "${execline}/bin/execlineb"
        "-S1"
        (copyPathToStore ./mda.elb)
        "$client_address"
      ]}"
    ];
  };
}