1 files changed, 57 insertions, 0 deletions
diff --git a/pkgs/development/mobile/ios-webkit-debug-proxy/default.nix b/pkgs/development/mobile/ios-webkit-debug-proxy/default.nix
new file mode 100644
index 000000000000..b9edbb4cbd4a
--- /dev/null
+++ b/pkgs/development/mobile/ios-webkit-debug-proxy/default.nix
@@ -0,0 +1,57 @@
+{ stdenv
+, autoconf
+, automake
+, fetchFromGitHub
+, fetchpatch
+, lib
+, libimobiledevice
+, libusb1
+, libplist
+, libtool
+, openssl
+, pkg-config
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ios-webkit-debug-proxy";
+  version = "1.9.0";
+
+  src = fetchFromGitHub {
+    owner = "google";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "sha256-cZ/p/aWET/BXKDrD+qgR+rfTISd+4jPNQFuV8klSLUo=";
+  };
+
+  patches = [
+    # OpenSSL 3.0 compatibility
+    (fetchpatch {
+      url = "https://github.com/google/ios-webkit-debug-proxy/commit/5ba30a2a67f39d25025cadf37c0eafb2e2d2d0a8.patch";
+      sha256 = "sha256-2b9BjG9wkqO+ZfoBYYJvD2Db5Kr0F/MxKMTRsI0ea3s=";
+    })
+    # Examples compilation breaks with --disable-static, see https://github.com/google/ios-webkit-debug-proxy/issues/399
+    ./0001-Don-t-compile-examples.patch
+  ];
+
+  outputs = [ "out" "dev" ];
+
+  nativeBuildInputs = [ autoconf automake libtool pkg-config ];
+  buildInputs = [ libimobiledevice libusb1 libplist openssl ];
+
+  preConfigure = ''
+    NOCONFIGURE=1 ./autogen.sh
+  '';
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    description = "A DevTools proxy (Chrome Remote Debugging Protocol) for iOS devices (Safari Remote Web Inspector).";
+    longDescription = ''
+      The ios_webkit_debug_proxy (aka iwdp) proxies requests from usbmuxd
+      daemon over a websocket connection, allowing developers to send commands
+      to MobileSafari and UIWebViews on real and simulated iOS devices.
+    '';
+    homepage = "https://github.com/google/ios-webkit-debug-proxy";
+    license = licenses.bsd3;
+    maintainers = [ maintainers.abustany ];
+  };
+}