1 files changed, 64 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/os-specific/linux/dpdk/default.nix b/nixpkgs/pkgs/os-specific/linux/dpdk/default.nix
new file mode 100644
index 000000000000..13614493f610
--- /dev/null
+++ b/nixpkgs/pkgs/os-specific/linux/dpdk/default.nix
@@ -0,0 +1,64 @@
+{ stdenv, lib, kernel, fetchurl, pkgconfig, numactl, shared ? false }:
+
+let
+
+  kver = kernel.modDirVersion or null;
+
+  mod = kernel != null;
+
+in stdenv.mkDerivation rec {
+  name = "dpdk-${version}" + lib.optionalString mod "-${kernel.version}";
+  version = "17.11.2";
+
+  src = fetchurl {
+    url = "https://fast.dpdk.org/rel/dpdk-${version}.tar.xz";
+    sha256 = "19m5l3jkrns8r1zbjb6ry18w50ff36kbl5b5g6pfcp9p57sfisd2";
+  };
+
+  nativeBuildInputs = [ pkgconfig ];
+  buildInputs = [ numactl ] ++ lib.optional mod kernel.moduleBuildDependencies;
+
+  RTE_KERNELDIR = if mod then "${kernel.dev}/lib/modules/${kver}/build" else "/var/empty";
+  RTE_TARGET = "x86_64-native-linuxapp-gcc";
+
+  # we need sse3 instructions to build
+  NIX_CFLAGS_COMPILE = [ "-msse3" ];
+  hardeningDisable = [ "pic" ];
+
+  postPatch = ''
+    cat >>config/defconfig_$RTE_TARGET <<EOF
+# Build static or shared libraries.
+CONFIG_RTE_BUILD_SHARED_LIB=${if shared then "y" else "n"}
+EOF
+  '' + lib.optionalString (!mod) ''
+    cat >>config/defconfig_$RTE_TARGET <<EOF
+# Do not build kernel modules.
+CONFIG_RTE_EAL_IGB_UIO=n
+CONFIG_RTE_KNI_KMOD=n
+EOF
+  '';
+
+  configurePhase = ''
+    make T=${RTE_TARGET} config
+  '';
+
+  installTargets = [ "install-runtime" "install-sdk" "install-kmod" ]; # skip install-doc
+
+  installFlags = [
+    "prefix=$(out)"
+  ] ++ lib.optionals mod [
+    "kerneldir=$(kmod)/lib/modules/${kver}"
+  ];
+
+  outputs = [ "out" ] ++ lib.optional mod "kmod";
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    description = "Set of libraries and drivers for fast packet processing";
+    homepage = http://dpdk.org/;
+    license = with licenses; [ lgpl21 gpl2 bsd2 ];
+    platforms =  [ "x86_64-linux" ];
+    maintainers = with maintainers; [ domenkozar orivej ];
+  };
+}