1 files changed, 40 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/tools/database/beekeeper-studio/default.nix b/nixpkgs/pkgs/development/tools/database/beekeeper-studio/default.nix
new file mode 100644
index 000000000000..74c5f35dc240
--- /dev/null
+++ b/nixpkgs/pkgs/development/tools/database/beekeeper-studio/default.nix
@@ -0,0 +1,40 @@
+{ lib, fetchurl, appimageTools, pkgs }:
+
+let
+  pname = "beekeeper-studio";
+  version = "2.1.4";
+  name = "${pname}-${version}";
+
+  src = fetchurl {
+    url = "https://github.com/beekeeper-studio/beekeeper-studio/releases/download/v${version}/Beekeeper-Studio-${version}.AppImage";
+    name="${pname}-${version}.AppImage";
+    sha512 = "1aik88wi9axv66axjmmjmlna1sp0pz92z8i2x6pq3bs0gcs4i1q3qxxbrfc14ynbpa65knimfhwzrrshchnijgdazx3qjzh8jwzfiwl";
+  };
+
+  appimageContents = appimageTools.extractType2 {
+    inherit name src;
+  };
+in appimageTools.wrapType2 {
+  inherit name src;
+
+  multiPkgs = null; # no 32bit needed
+  extraPkgs = pkgs: appimageTools.defaultFhsEnvArgs.multiPkgs pkgs ++ [ pkgs.bash ];
+
+  extraInstallCommands = ''
+    ln -s $out/bin/${name} $out/bin/${pname}
+    install -m 444 -D ${appimageContents}/${pname}.desktop $out/share/applications/${pname}.desktop
+    install -m 444 -D ${appimageContents}/${pname}.png \
+      $out/share/icons/hicolor/512x512/apps/${pname}.png
+    substituteInPlace $out/share/applications/${pname}.desktop \
+      --replace 'Exec=AppRun' 'Exec=${pname}'
+  '';
+
+  meta = with lib; {
+    description = "Modern and easy to use SQL client for MySQL, Postgres, SQLite, SQL Server, and more. Linux, MacOS, and Windows";
+    homepage = "https://www.beekeeperstudio.io";
+    changelog = "https://github.com/beekeeper-studio/beekeeper-studio/releases/tag/v2.1.4";
+    license = licenses.mit;
+    maintainers = with maintainers; [ milogert ];
+    platforms = [ "x86_64-linux" ];
+  };
+}