1 files changed, 33 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/libraries/librclone/default.nix b/nixpkgs/pkgs/development/libraries/librclone/default.nix
new file mode 100644
index 000000000000..3b8bf83364c9
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/librclone/default.nix
@@ -0,0 +1,33 @@
+{ lib
+, stdenv
+, buildGoModule
+, rclone
+}:
+
+let
+  ext = stdenv.hostPlatform.extensions.sharedLibrary;
+in buildGoModule rec {
+  pname = "librclone";
+  inherit (rclone) version src vendorSha256;
+
+  buildPhase = ''
+    runHook preBuild
+    cd librclone
+    go build --buildmode=c-shared -o librclone${ext} github.com/rclone/rclone/librclone
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    install -Dt $out/lib librclone${ext}
+    install -Dt $out/include librclone.h
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Rclone as a C library";
+    homepage = "https://github.com/rclone/rclone/tree/master/librclone";
+    maintainers = with lib.maintainers; [ dotlambda ];
+    inherit (rclone.meta) license platforms;
+  };
+}