1 files changed, 54 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/by-name/ni/nicotine-plus/package.nix b/nixpkgs/pkgs/by-name/ni/nicotine-plus/package.nix
new file mode 100644
index 000000000000..dad01456ba73
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/ni/nicotine-plus/package.nix
@@ -0,0 +1,54 @@
+{ lib
+, fetchFromGitHub
+, wrapGAppsHook4
+, gdk-pixbuf
+, gettext
+, gobject-introspection
+, gtk4
+, python3Packages
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "nicotine-plus";
+  version = "3.3.2";
+
+  src = fetchFromGitHub {
+    owner = "nicotine-plus";
+    repo = "nicotine-plus";
+    rev = "refs/tags/${version}";
+    hash = "sha256-dl4fTa+CXsycC+hhSkIzQQxrSkBDPsdrmKdrHPakGig=";
+  };
+
+  nativeBuildInputs = [ gettext wrapGAppsHook4 gobject-introspection ];
+
+  propagatedBuildInputs = [
+    gdk-pixbuf
+    gobject-introspection
+    gtk4
+    python3Packages.pygobject3
+  ];
+
+  postInstall = ''
+    ln -s $out/bin/nicotine $out/bin/nicotine-plus
+  '';
+
+  preFixup = ''
+    gappsWrapperArgs+=(
+      --prefix XDG_DATA_DIRS : "${gtk4}/share/gsettings-schemas/${gtk4.name}"
+    )
+  '';
+
+  doCheck = false;
+
+  meta = with lib; {
+    description = "A graphical client for the SoulSeek peer-to-peer system";
+    longDescription = ''
+      Nicotine+ aims to be a pleasant, free and open source (FOSS) alternative
+      to the official Soulseek client, providing additional functionality while
+      keeping current with the Soulseek protocol.
+    '';
+    homepage = "https://www.nicotine-plus.org";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ klntsky ];
+  };
+}