1 files changed, 66 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/by-name/cl/clash-verge/package.nix b/nixpkgs/pkgs/by-name/cl/clash-verge/package.nix
new file mode 100644
index 000000000000..1a8d6a99198e
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/cl/clash-verge/package.nix
@@ -0,0 +1,66 @@
+{ lib
+, stdenv
+, fetchurl
+, dpkg
+, wrapGAppsHook
+, autoPatchelfHook
+, clash-meta
+, openssl
+, webkitgtk
+, udev
+, libayatana-appindicator
+, nix-update-script
+}:
+
+stdenv.mkDerivation rec {
+  pname = "clash-verge";
+  version = "1.3.8";
+
+  src = fetchurl {
+    url = "https://github.com/zzzgydi/clash-verge/releases/download/v${version}/clash-verge_${version}_amd64.deb";
+    hash = "sha256-kOju4yaa+EKzFWDrk0iSJVoWkQMBjQG3hKLfAsqlsy8=";
+  };
+
+  nativeBuildInputs = [
+    dpkg
+    wrapGAppsHook
+    autoPatchelfHook
+  ];
+
+  buildInputs = [
+    openssl
+    webkitgtk
+    stdenv.cc.cc
+  ];
+
+  runtimeDependencies = [
+    (lib.getLib udev)
+    libayatana-appindicator
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    mv usr/* $out
+
+    runHook postInstall
+  '';
+
+  postFixup = ''
+    rm -f $out/bin/clash
+    ln -sf ${lib.getExe clash-meta} $out/bin/${clash-meta.meta.mainProgram}
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = with lib; {
+    description = "A Clash GUI based on tauri";
+    homepage = "https://github.com/zzzgydi/clash-verge";
+    platforms = [ "x86_64-linux" ];
+    license = licenses.gpl3Plus;
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+    maintainers = with maintainers; [ zendo ];
+    mainProgram = "clash-verge";
+  };
+}