buildbot: add Python 3 support

8 files changed, 98 insertions, 97 deletions

diff --git a/pkgs/development/tools/build-managers/buildbot/default.nix b/pkgs/development/python-modules/buildbot/default.nix
index 7e89fdc348eb..0110aa92c061 100644
--- a/pkgs/development/tools/build-managers/buildbot/default.nix
+++ b/pkgs/development/python-modules/buildbot/default.nix
@@ -1,72 +1,68 @@
-{ stdenv, openssh, buildbot-worker, buildbot-pkg, pythonPackages, runCommand, makeWrapper }:
+{ stdenv, lib, buildPythonPackage, fetchPypi, makeWrapper, isPy3k,
+  python, twisted, jinja2, zope_interface, future, sqlalchemy,
+  sqlalchemy_migrate, dateutil, txaio, autobahn, pyjwt, treq, txrequests,
+  txgithub, pyjade, boto3, moto, mock, lz4, setuptoolsTrial, isort, pylint,
+  flake8, buildbot-worker, buildbot-pkg, glibcLocales }:
 
 let
-  withPlugins = plugins: runCommand "wrapped-${package.name}" {
-    buildInputs = [ makeWrapper ] ++ plugins;
-    propagatedBuildInputs = package.propagatedBuildInputs;
-    passthru.withPlugins = moarPlugins: withPlugins (moarPlugins ++ plugins);
-  } ''
-    makeWrapper ${package}/bin/buildbot $out/bin/buildbot \
-      --prefix PYTHONPATH : "${package}/lib/python2.7/site-packages:$PYTHONPATH"
-    ln -sfv ${package}/lib $out/lib
-  '';
+  withPlugins = plugins: buildPythonPackage {
+    name = "${package.name}-with-plugins";
+    phases = [ "installPhase" "fixupPhase" ];
+    buildInputs = [ makeWrapper ];
+    propagatedBuildInputs = plugins ++ package.propagatedBuildInputs;
 
-  package = pythonPackages.buildPythonApplication rec {
+    installPhase = ''
+      makeWrapper ${package}/bin/buildbot $out/bin/buildbot \
+        --prefix PYTHONPATH : "${package}/${python.sitePackages}:$PYTHONPATH"
+      ln -sfv ${package}/lib $out/lib
+    '';
+
+    passthru = package.passthru // {
+      withPlugins = morePlugins: withPlugins (morePlugins ++ plugins);
+    };
+  };
+
+  package = buildPythonPackage rec {
     pname = "buildbot";
     version = "1.4.0";
 
-    src = pythonPackages.fetchPypi {
+    src = fetchPypi {
       inherit pname version;
       sha256 = "0dfa926nh642i3bnpzlz0q347zicyx6wswjfqbniri59ya64fncx";
     };
 
-    buildInputs = with pythonPackages; [
-      lz4
-      txrequests
-      pyjade
-      boto3
-      moto
-      txgithub
-      mock
-      setuptoolsTrial
-      isort
-      pylint
-      astroid
-      pyflakes
-      openssh
-      buildbot-worker
-      buildbot-pkg
-      treq
-    ];
-
-    propagatedBuildInputs = with pythonPackages; [
+    propagatedBuildInputs = [
       # core
       twisted
       jinja2
       zope_interface
+      future
       sqlalchemy
       sqlalchemy_migrate
-      future
       dateutil
       txaio
       autobahn
       pyjwt
-      distro
 
       # tls
-      pyopenssl
-      service-identity
-      idna
-
-      # docs
-      sphinx
-      sphinxcontrib-blockdiag
-      sphinxcontrib-spelling
-      pyenchant
-      docutils
-      ramlfications
-      sphinx-jinja
+      twisted.extras.tls
+    ];
 
+    checkInputs = [
+      treq
+      txrequests
+      pyjade
+      boto3
+      moto
+      mock
+      lz4
+      setuptoolsTrial
+      isort
+      pylint
+      flake8
+      buildbot-worker
+      buildbot-pkg
+      glibcLocales
     ];
 
     patches = [
@@ -75,6 +71,8 @@ let
       ./skip_test_linux_distro.patch
     ];
 
+    LC_ALL = "en_US.UTF-8";
+
     # TimeoutErrors on slow machines -> aarch64
     doCheck = !stdenv.isAarch64;
 
@@ -82,9 +80,11 @@ let
       substituteInPlace buildbot/scripts/logwatcher.py --replace '/usr/bin/tail' "$(type -P tail)"
     '';
 
-    passthru = { inherit withPlugins; };
+    passthru = {
+      inherit withPlugins;
+    };
 
-    meta = with stdenv.lib; {
+    meta = with lib; {
       homepage = http://buildbot.net/;
       description = "Buildbot is an open-source continuous integration framework for automating software build, test, and release processes";
       maintainers = with maintainers; [ nand0p ryansydnor ];
diff --git a/pkgs/development/tools/build-managers/buildbot/pkg.nix b/pkgs/development/python-modules/buildbot/pkg.nix
index 452c2ffea04a..b9358b1c420b 100644
--- a/pkgs/development/tools/build-managers/buildbot/pkg.nix
+++ b/pkgs/development/python-modules/buildbot/pkg.nix
@@ -1,4 +1,4 @@
-{ stdenv, buildPythonPackage, fetchPypi, setuptools }:
+{ lib, buildPythonPackage, fetchPypi, setuptools }:
 
 buildPythonPackage rec {
   pname = "buildbot-pkg";
@@ -15,7 +15,7 @@ buildPythonPackage rec {
     substituteInPlace buildbot_pkg.py --replace "os.listdir = listdir" ""
   '';
 
-  meta = with stdenv.lib; {
+  meta = with lib; {
     homepage = http://buildbot.net/;
     description = "Buildbot Packaging Helper";
     maintainers = with maintainers; [ nand0p ryansydnor ];
diff --git a/pkgs/development/tools/build-managers/buildbot/plugins.nix b/pkgs/development/python-modules/buildbot/plugins.nix
index 91499b6e755c..bdc67d178d44 100644
--- a/pkgs/development/tools/build-managers/buildbot/plugins.nix
+++ b/pkgs/development/python-modules/buildbot/plugins.nix
@@ -1,19 +1,19 @@
-{ stdenv, pythonPackages, buildbot-pkg }:
+{ lib, buildPythonPackage, fetchPypi, buildbot, buildbot-pkg }:
 
 {
-  www = pythonPackages.buildPythonPackage rec {
+  www = buildPythonPackage rec {
     pname = "buildbot_www";
-    version = buildbot-pkg.version;
+    inherit (buildbot-pkg) version;
 
     # NOTE: wheel is used due to buildbot circular dependency
     format = "wheel";
 
-    src = pythonPackages.fetchPypi {
+    src = fetchPypi {
       inherit pname version format;
       sha256 = "1m5dsp1gn9m5vfh5hnqp8g6hmhw1f1ydnassd33nhk521f2akz0v";
     };
 
-    meta = with stdenv.lib; {
+    meta = with lib; {
       homepage = http://buildbot.net/;
       description = "Buildbot UI";
       maintainers = with maintainers; [ nand0p ryansydnor ];
@@ -21,18 +21,19 @@
     };
   };
 
-  console-view = pythonPackages.buildPythonPackage rec {
+  console-view = buildPythonPackage rec {
     pname = "buildbot-console-view";
-    version = buildbot-pkg.version;
+    inherit (buildbot-pkg) version;
 
-    src = pythonPackages.fetchPypi {
+    src = fetchPypi {
       inherit pname version;
       sha256 = "0vblaxmihgb4w9aa5q0wcgvxs7qzajql8s22w0pl9qs494g05s9r";
     };
 
-    propagatedBuildInputs = with pythonPackages; [ buildbot-pkg ];
+    propagatedBuildInputs = [ buildbot-pkg ];
+    checkInputs = [ buildbot ];
 
-    meta = with stdenv.lib; {
+    meta = with lib; {
       homepage = http://buildbot.net/;
       description = "Buildbot Console View Plugin";
       maintainers = with maintainers; [ nand0p ryansydnor ];
@@ -40,18 +41,19 @@
     };
   };
 
-  waterfall-view = pythonPackages.buildPythonPackage rec {
+  waterfall-view = buildPythonPackage rec {
     pname = "buildbot-waterfall-view";
-    version = buildbot-pkg.version;
+    inherit (buildbot-pkg) version;
 
-    src = pythonPackages.fetchPypi {
+    src = fetchPypi {
       inherit pname version;
       sha256 = "18v1a6dapwjc2s9hi0cv3ry3s048w84md908zwaa3033gz3zwzy7";
     };
 
-    propagatedBuildInputs = with pythonPackages; [ buildbot-pkg ];
+    propagatedBuildInputs = [ buildbot-pkg ];
+    checkInputs = [ buildbot ];
 
-    meta = with stdenv.lib; {
+    meta = with lib; {
       homepage = http://buildbot.net/;
       description = "Buildbot Waterfall View Plugin";
       maintainers = with maintainers; [ nand0p ryansydnor ];
@@ -59,18 +61,19 @@
     };
   };
 
-  grid-view = pythonPackages.buildPythonPackage rec {
+  grid-view = buildPythonPackage rec {
     pname = "buildbot-grid-view";
-    version = buildbot-pkg.version;
+    inherit (buildbot-pkg) version;
 
-    src = pythonPackages.fetchPypi {
+    src = fetchPypi {
       inherit pname version;
       sha256 = "0iawsy892v6rn88hsgiiwaf689jqzhnb2wbxh6zkz3c0hvq4g0qd";
     };
 
-    propagatedBuildInputs = with pythonPackages; [ buildbot-pkg ];
+    propagatedBuildInputs = [ buildbot-pkg ];
+    checkInputs = [ buildbot ];
 
-    meta = with stdenv.lib; {
+    meta = with lib; {
       homepage = http://buildbot.net/;
       description = "Buildbot Grid View Plugin";
       maintainers = with maintainers; [ nand0p ];
@@ -78,23 +81,23 @@
     };
   };
 
-  wsgi-dashboards = pythonPackages.buildPythonPackage rec {
+  wsgi-dashboards = buildPythonPackage rec {
     pname = "buildbot-wsgi-dashboards";
-    version = buildbot-pkg.version;
+    inherit (buildbot-pkg) version;
 
-    src = pythonPackages.fetchPypi {
+    src = fetchPypi {
       inherit pname version;
       sha256 = "00cpjna3bffh1qbq6a3sqffd1g7qhbrmn9gpzxf9k38jam6jgfpz";
     };
 
-    propagatedBuildInputs = with pythonPackages; [ buildbot-pkg ];
+    propagatedBuildInputs = [ buildbot-pkg ];
+    checkInputs = [ buildbot ];
 
-    meta = with stdenv.lib; {
+    meta = with lib; {
       homepage = http://buildbot.net/;
       description = "Buildbot WSGI dashboards Plugin";
       maintainers = with maintainers; [ ];
       license = licenses.gpl2;
     };
   };
-
 }
diff --git a/pkgs/development/tools/build-managers/buildbot/skip_test_linux_distro.patch b/pkgs/development/python-modules/buildbot/skip_test_linux_distro.patch
index 8fe5c7b56b4f..8fe5c7b56b4f 100644
--- a/pkgs/development/tools/build-managers/buildbot/skip_test_linux_distro.patch
+++ b/pkgs/development/python-modules/buildbot/skip_test_linux_distro.patch
diff --git a/pkgs/development/tools/build-managers/buildbot/worker.nix b/pkgs/development/python-modules/buildbot/worker.nix
index 02beb686399d..4e54276f8aed 100644
--- a/pkgs/development/tools/build-managers/buildbot/worker.nix
+++ b/pkgs/development/python-modules/buildbot/worker.nix
@@ -1,22 +1,23 @@
-{ stdenv, pythonPackages }:
+{ lib, buildPythonPackage, fetchPypi, python, setuptoolsTrial, mock, twisted, future }:
 
-pythonPackages.buildPythonApplication (rec {
+buildPythonPackage (rec {
   pname = "buildbot-worker";
   version = "1.4.0";
 
-  src = pythonPackages.fetchPypi {
+  src = fetchPypi {
     inherit pname version;
     sha256 = "12zvf4c39b6s4g1f2w407q8kkw602m88rc1ggi4w9pkw3bwbxrgy";
   };
 
-  buildInputs = with pythonPackages; [ setuptoolsTrial mock ];
-  propagatedBuildInputs = with pythonPackages; [ twisted future ];
+  propagatedBuildInputs = [ twisted future ];
+
+  checkInputs = [ setuptoolsTrial mock ];
 
   postPatch = ''
     substituteInPlace buildbot_worker/scripts/logwatcher.py --replace '/usr/bin/tail' "$(type -P tail)"
   '';
 
-  meta = with stdenv.lib; {
+  meta = with lib; {
     homepage = http://buildbot.net/;
     description = "Buildbot Worker Daemon";
     maintainers = with maintainers; [ nand0p ryansydnor ];
diff --git a/pkgs/top-level/aliases.nix b/pkgs/top-level/aliases.nix
index fe0d3816413e..0abf0e608466 100644
--- a/pkgs/top-level/aliases.nix
+++ b/pkgs/top-level/aliases.nix
@@ -49,6 +49,11 @@ mapAliases ({
   bashCompletion = bash-completion; # Added 2016-09-28
   bridge_utils = bridge-utils;  # added 2015-02-20
   btrfsProgs = btrfs-progs; # added 2016-01-03
+  buildbot = pythonPackages.buildbot; # added 2018-10-11
+  buildbot-full = pythonPackages.buildbot-full; # added 2018-10-11
+  buildbot-pkg = pythonPackages.buildbot-pkg; # added 2018-10-11
+  buildbot-ui = pythonPackages.buildbot-ui; # added 2018-10-11
+  buildbot-worker = pythonPackages.buildbot-worker; # added 2018-10-11
   bundler_HEAD = bundler; # added 2015-11-15
   cantarell_fonts = cantarell-fonts; # added 2018-03-03
   checkbashism = checkbashisms; # added 2016-08-16
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index d911181ae372..b34501a8f69f 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -8135,21 +8135,6 @@ with pkgs;
 
   buck = callPackage ../development/tools/build-managers/buck { };
 
-  buildbot = callPackage ../development/tools/build-managers/buildbot {
-    pythonPackages = python2Packages;
-  };
-  buildbot-worker = callPackage ../development/tools/build-managers/buildbot/worker.nix {
-    pythonPackages = python2Packages;
-  };
-  buildbot-pkg = callPackage ../development/tools/build-managers/buildbot/pkg.nix {
-    inherit (python2Packages) buildPythonPackage fetchPypi setuptools;
-  };
-  buildbot-plugins = callPackages ../development/tools/build-managers/buildbot/plugins.nix {
-    pythonPackages = python2Packages;
-  };
-  buildbot-ui = buildbot.withPlugins (with self.buildbot-plugins; [ www ]);
-  buildbot-full = buildbot.withPlugins (with self.buildbot-plugins; [ www console-view waterfall-view grid-view wsgi-dashboards ]);
-
   buildkite-agent = buildkite-agent2;
   buildkite-agent2 = callPackage ../development/tools/continuous-integration/buildkite-agent/2.x.nix { };
   buildkite-agent3 = callPackage ../development/tools/continuous-integration/buildkite-agent/3.x.nix { };
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 73d2cf6d2ac6..3822f08bad7b 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -1421,6 +1421,13 @@ in {
 
   bugzilla = callPackage ../development/python-modules/bugzilla { };
 
+  buildbot = callPackage ../development/python-modules/buildbot { };
+  buildbot-plugins = pkgs.recurseIntoAttrs (callPackage ../development/python-modules/buildbot/plugins.nix { });
+  buildbot-ui = self.buildbot.withPlugins (with self.buildbot-plugins; [ www ]);
+  buildbot-full = self.buildbot.withPlugins (with self.buildbot-plugins; [ www console-view waterfall-view grid-view wsgi-dashboards ]);
+  buildbot-worker = callPackage ../development/python-modules/buildbot/worker.nix { };
+  buildbot-pkg = callPackage ../development/python-modules/buildbot/pkg.nix { };
+
   check-manifest = callPackage ../development/python-modules/check-manifest { };
 
   devpi-common = callPackage ../development/python-modules/devpi-common { };