udiskie: move to all-packages

This is an application, not a python library and should therefore be in
its own package.

3 files changed, 47 insertions, 43 deletions

diff --git a/pkgs/applications/misc/udiskie/default.nix b/pkgs/applications/misc/udiskie/default.nix
new file mode 100644
index 000000000000..042401a727e9
--- /dev/null
+++ b/pkgs/applications/misc/udiskie/default.nix
@@ -0,0 +1,43 @@
+{ stdenv, fetchFromGitHub, asciidoc-full, gettext
+, gobjectIntrospection, gtk3, hicolor_icon_theme, libnotify
+, pythonPackages, udisks2, wrapGAppsHook }:
+
+pythonPackages.buildPythonApplication rec {
+  name = "udiskie-${version}";
+  version = "1.5.1";
+
+  src = fetchFromGitHub {
+    owner = "coldfix";
+    repo = "udiskie";
+    rev = version;
+    sha256 = "01x5fvllb262x6r3547l23z7p6hr7ddz034bkhmj2cqmf83sxwxd";
+  };
+
+  buildInputs = [
+    asciidoc-full        # For building man page.
+    hicolor_icon_theme
+    wrapGAppsHook
+  ];
+
+  propagatedBuildInputs = [
+    gettext gobjectIntrospection gtk3 libnotify pythonPackages.docopt
+    pythonPackages.pygobject3 pythonPackages.pyyaml udisks2
+  ];
+
+  postBuild = "make -C doc";
+
+  postInstall = ''
+    mkdir -p $out/share/man/man8
+    cp -v doc/udiskie.8 $out/share/man/man8/
+  '';
+
+  # tests require dbusmock
+  doCheck = false;
+
+  meta = with stdenv.lib; {
+    description = "Removable disk automounter for udisks";
+    license = licenses.mit;
+    homepage = https://github.com/coldfix/udiskie;
+    maintainers = with maintainers; [ AndersonTorres ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 86fa34a3b430..edb3a0da39e7 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -14672,6 +14672,8 @@ in
 
   udevil = callPackage ../applications/misc/udevil {};
 
+  udiskie = callPackage ../applications/misc/udiskie { };
+
   sakura = callPackage ../applications/misc/sakura {
     vte = gnome3.vte;
   };
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index b446708824d7..02c2408ac639 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -27121,49 +27121,8 @@ in modules // {
     };
   };
 
-  udiskie = buildPythonApplication rec {
-    version = "1.5.1";
-    name = "udiskie-${version}";
-
-    src = pkgs.fetchFromGitHub {
-      owner = "coldfix";
-      repo = "udiskie";
-      rev = version;
-      sha256 = "01x5fvllb262x6r3547l23z7p6hr7ddz034bkhmj2cqmf83sxwxd";
-    };
-
-    preConfigure = ''
-      export XDG_RUNTIME_DIR=/tmp
-    '';
-
-    buildInputs = [
-      pkgs.asciidoc-full        # For building man page.
-      pkgs.hicolor_icon_theme
-      pkgs.wrapGAppsHook
-    ];
-
-    propagatedBuildInputs = with self; [
-      pkgs.gobjectIntrospection pkgs.gtk3 pyyaml pygobject3
-      pkgs.libnotify pkgs.udisks2 pkgs.gettext self.docopt
-    ];
-
-    postBuild = "make -C doc";
-
-    postInstall = ''
-      mkdir -p $out/share/man/man8
-      cp -v doc/udiskie.8 $out/share/man/man8/
-    '';
-
-    # tests require dbusmock
-    doCheck = false;
-
-    meta = {
-      description = "Removable disk automounter for udisks";
-      license = licenses.mit;
-      homepage = https://github.com/coldfix/udiskie;
-      maintainers = with maintainers; [ AndersonTorres ];
-    };
-  };
+  # For backwards compatibility. Please use nixpkgs.udiskie instead.
+  udiskie = pkgs.udiskie.override { pythonPackages = self; };
 
   # Should be bumped along with EFL!
   pythonefl = buildPythonPackage rec {