gnupg: Add gnupg 2.1 as default

Additionally, move all gnupg expressions into the gnupg folder.

4 files changed, 71 insertions, 0 deletions

diff --git a/pkgs/tools/security/gnupg/1.nix b/pkgs/tools/security/gnupg/1.nix
new file mode 100644
index 000000000000..3675c8bc390f
--- /dev/null
+++ b/pkgs/tools/security/gnupg/1.nix
@@ -0,0 +1,21 @@
+{ stdenv, fetchurl, readline, bzip2 }:
+
+stdenv.mkDerivation rec {
+  name = "gnupg-1.4.18";
+
+  src = fetchurl {
+    url = "mirror://gnupg/gnupg/${name}.tar.bz2";
+    sha256 = "1233bppjvdpbbl425ii6l7xvgy0879ghhnmwrph5b6c4g3dgvddp";
+  };
+
+  buildInputs = [ readline bzip2 ];
+
+  doCheck = true;
+
+  meta = {
+    description = "free implementation of the OpenPGP standard for encrypting and signing data";
+    homepage = http://www.gnupg.org/;
+    license = stdenv.lib.licenses.gpl3Plus;
+    platforms = stdenv.lib.platforms.gnu; # arbitrary choice
+  };
+}
diff --git a/pkgs/tools/security/gnupg/1compat.nix b/pkgs/tools/security/gnupg/1compat.nix
new file mode 100644
index 000000000000..9bd71467f0ea
--- /dev/null
+++ b/pkgs/tools/security/gnupg/1compat.nix
@@ -0,0 +1,20 @@
+{ stdenv, gnupg, coreutils, writeScript }:
+
+stdenv.mkDerivation {
+  name = "gnupg1compat-0";
+
+  builder = writeScript "gnupg1compat-builder" ''
+    # First symlink all top-level dirs
+    ${coreutils}/bin/mkdir -p $out
+    ${coreutils}/bin/ln -s ${gnupg}/* $out
+
+    # Replace bin with directory and symlink it contents
+    ${coreutils}/bin/rm $out/bin
+    ${coreutils}/bin/mkdir -p $out/bin
+    ${coreutils}/bin/ln -s ${gnupg}/bin/* $out/bin
+
+    # Add gpg->gpg2 and gpgv->gpgv2 symlinks
+    ${coreutils}/bin/ln -s gpg2 $out/bin/gpg
+    ${coreutils}/bin/ln -s gpgv2 $out/bin/gpgv
+  '';
+}
diff --git a/pkgs/tools/security/gnupg/default.nix b/pkgs/tools/security/gnupg/20.nix
index 45a25d7e2422..45a25d7e2422 100644
--- a/pkgs/tools/security/gnupg/default.nix
+++ b/pkgs/tools/security/gnupg/20.nix
diff --git a/pkgs/tools/security/gnupg/21.nix b/pkgs/tools/security/gnupg/21.nix
new file mode 100644
index 000000000000..8c3854ac23d6
--- /dev/null
+++ b/pkgs/tools/security/gnupg/21.nix
@@ -0,0 +1,30 @@
+{ fetchurl, stdenv, pkgconfig, libgcrypt, libassuan, libksba, npth
+, readline ? null, libusb ? null, gnutls ? null, adns ? null, openldap ? null
+, zlib ? null, bzip2 ? null, pinentry ? null
+}:
+
+with stdenv.lib;
+stdenv.mkDerivation rec {
+  name = "gnupg-2.1.0";
+
+  src = fetchurl {
+    url = "mirror://gnupg/gnupg/${name}.tar.bz2";
+    sha256 = "12q5shx6ldqad3rky154nv8f2cy57sxy9idivz93ggqm1bsw7a0n";
+  };
+
+  buildInputs = [
+    pkgconfig libgcrypt libassuan libksba npth
+    readline libusb gnutls adns openldap zlib bzip2
+  ];
+
+  configureFlags =
+    optional (pinentry != null) "--with-pinentry-pgm=${pinentry}/bin/pinentry";
+
+  meta = with stdenv.lib; {
+    homepage = http://gnupg.org;
+    description = "a complete and free implementation of the OpenPGP standard";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ wkennington ];
+    platforms = platforms.all;
+  };
+}