treewide: rename bad filenames

Most of these can easily be moved to subdirectories of other
directories. This helps reduce clutter in the main trees.

5 files changed, 184 insertions, 0 deletions

diff --git a/pkgs/tools/networking/connman/connman-gtk/default.nix b/pkgs/tools/networking/connman/connman-gtk/default.nix
new file mode 100644
index 000000000000..d5688354a76d
--- /dev/null
+++ b/pkgs/tools/networking/connman/connman-gtk/default.nix
@@ -0,0 +1,43 @@
+{ stdenv, fetchFromGitHub, autoconf, automake, intltool, pkgconfig,
+gtk3, connman, openconnect, wrapGAppsHook }:
+
+stdenv.mkDerivation rec {
+  name = "connman-gtk-${version}";
+  version = "1.1.1";
+
+  src = fetchFromGitHub {
+    owner = "jgke";
+    repo = "connman-gtk";
+    rev = "v${version}";
+    sha256 = "09k0hx5hxpbykvslv12l2fq9pxdwpd311mxj038hbqzjghcyidyr";
+  };
+
+  nativeBuildInputs = [
+    autoconf
+    automake
+    intltool
+    pkgconfig
+    wrapGAppsHook
+  ];
+
+  buildInputs = [
+    gtk3
+    openconnect
+    connman
+  ];
+
+  preConfigure = ''
+    # m4/intltool.m4 is an invalid symbolic link
+    rm m4/intltool.m4
+    ln -s ${intltool}/share/aclocal/intltool.m4 m4/
+    ./autogen.sh
+  '';
+
+  meta = with stdenv.lib; {
+    description = "GTK GUI for Connman";
+    homepage = https://github.com/jgke/connman-gtk;
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.romildo ];
+  };
+}
diff --git a/pkgs/tools/networking/connman/connman-ncurses/default.nix b/pkgs/tools/networking/connman/connman-ncurses/default.nix
new file mode 100644
index 000000000000..8c4d4fa84865
--- /dev/null
+++ b/pkgs/tools/networking/connman/connman-ncurses/default.nix
@@ -0,0 +1,32 @@
+{ stdenv, fetchFromGitHub, autoreconfHook, pkgconfig, dbus, json_c, ncurses, connman }:
+
+stdenv.mkDerivation rec {
+  name = "connman-ncurses-${version}";
+  version = "2015-07-21";
+
+  src = fetchFromGitHub {
+    owner = "eurogiciel-oss";
+    repo = "connman-json-client";
+    rev = "3c34b2ee62d2e188090d20e7ed2fd94bab9c47f2";
+    sha256 = "1831r0776fv481g8kgy1dkl750pzv47835dw11sslq2k6mm6i9p1";
+  };
+
+  nativeBuildInputs = [ autoreconfHook pkgconfig ];
+
+  buildInputs = [ dbus ncurses json_c connman ];
+
+  NIX_CFLAGS_COMPILE = "-Wno-error";
+  
+  installPhase = ''
+    mkdir -p "$out/bin"
+    cp -va connman_ncurses "$out/bin/"
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Simple ncurses UI for connman";
+    homepage = https://github.com/eurogiciel-oss/connman-json-client;
+    license = licenses.gpl2;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.romildo ];
+  };
+}
diff --git a/pkgs/tools/networking/connman/connman-notify/default.nix b/pkgs/tools/networking/connman/connman-notify/default.nix
new file mode 100644
index 000000000000..42b0c37411c8
--- /dev/null
+++ b/pkgs/tools/networking/connman/connman-notify/default.nix
@@ -0,0 +1,40 @@
+{ stdenv, fetchFromGitHub, pythonPackages, makeWrapper }:
+
+stdenv.mkDerivation rec {
+  name = "connman-notify-${version}";
+  version = "2014-06-23";
+
+  src = fetchFromGitHub {
+    owner = "wavexx";
+    repo = "connman-notify";
+    rev = "0ed9b5e4a0e1f03c83c4589cabf410cac66cd11d";
+    sha256 = "0lhk417fdg3qxs1marpqp277bdxhwnbyrld9xj224bfk5v7xi4bg";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  buildInputs = [
+    pythonPackages.python
+    pythonPackages.dbus-python
+    pythonPackages.pygobject2
+    pythonPackages.pygtk
+    pythonPackages.notify
+  ];
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp -vai connman-notify $out/bin/
+  '';
+
+  preFixup = ''
+    wrapProgram $out/bin/connman-notify --prefix PYTHONPATH : "$PYTHONPATH"
+  '';  
+
+  meta = with stdenv.lib; {
+    description = "Desktop notification integration for connman";
+    homepage = https://github.com/wavexx/connman-notify;
+    license = licenses.gpl2;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.romildo ];
+  };
+}
diff --git a/pkgs/tools/networking/connman/connman_dmenu/default.nix b/pkgs/tools/networking/connman/connman_dmenu/default.nix
new file mode 100644
index 000000000000..c39c82df634c
--- /dev/null
+++ b/pkgs/tools/networking/connman/connman_dmenu/default.nix
@@ -0,0 +1,35 @@
+{ stdenv, fetchFromGitHub, connman, dmenu }:
+
+stdenv.mkDerivation rec {
+  name = "connman_dmenu-${version}";
+  version = "git-29-9-2015";
+
+  src = fetchFromGitHub {
+    owner = "march-linux";
+    repo = "connman_dmenu";
+    rev = "cc89fec40b574b0d234afeb70ea3c94626ca3f5c";
+    sha256 = "061fi83pai4n19l9d7wq6wwj2d7cixwkhkh742c5ibmw1wb274yk";
+  };
+
+  buildInputs = [ connman dmenu ];
+
+  dontBuild = true;
+
+  # remove root requirement, see: https://github.com/march-linux/connman_dmenu/issues/3
+  postPatch = ''
+    sed -i '89,92d' connman_dmenu
+  '';
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp connman_dmenu $out/bin/
+  '';
+
+  meta = {
+    description  = "A dmenu wrapper for connmann";
+    homepage     = https://github.com/march-linux/connman_dmenu;
+    license      = stdenv.lib.licenses.free;
+    maintainers  = [ stdenv.lib.maintainers.magnetophon ];
+    platforms    = stdenv.lib.platforms.all;
+  };
+}
diff --git a/pkgs/tools/networking/connman/connmanui/default.nix b/pkgs/tools/networking/connman/connmanui/default.nix
new file mode 100644
index 000000000000..7c42cc965a00
--- /dev/null
+++ b/pkgs/tools/networking/connman/connmanui/default.nix
@@ -0,0 +1,34 @@
+{ stdenv, fetchgit, autoconf, automake, libtool, glib, gtk3, dbus, pkgconfig, file, intltool, connman }:
+
+stdenv.mkDerivation rec {
+  name = "connmanui-${version}";
+  rev = "fce0af94e121bde77c7fa2ebd6a319f0180c5516";
+  version = "22062015-${rev}";
+
+  src = fetchgit {
+    inherit rev;
+    url = "git://github.com/tbursztyka/connman-ui.git";
+    sha256 = "0ixx8c9cfdp480z21xfjb7n1x27sf1g8gmgbmcfhr0k888dmziyy";
+  };
+
+  nativeBuildInputs = [ pkgconfig ];
+  buildInputs = [ autoconf automake libtool glib gtk3 dbus file intltool connman ];
+
+  preConfigure = ''
+    rm m4/intltool.m4
+    ln -s ${intltool}/share/aclocal/intltool.m4 m4/
+    set -e
+    ./autogen.sh
+    sed -i "s/\/usr\/bin\/file/file/g" ./configure
+  '';
+
+  configureScript = "./configure";
+
+  meta = {
+    description = "A full-featured GTK based trayicon UI for ConnMan";
+    homepage = https://github.com/tbursztyka/connman-ui;
+    maintainers = [ stdenv.lib.maintainers.matejc ];
+    platforms = stdenv.lib.platforms.linux;
+    license = stdenv.lib.licenses.gpl2;
+  };
+}