spicetify-cli: migrate to by-name

1 files changed, 46 insertions, 0 deletions

diff --git a/pkgs/by-name/sp/spicetify-cli/package.nix b/pkgs/by-name/sp/spicetify-cli/package.nix
new file mode 100644
index 000000000000..7447f934c82e
--- /dev/null
+++ b/pkgs/by-name/sp/spicetify-cli/package.nix
@@ -0,0 +1,46 @@
+{ lib, buildGoModule, fetchFromGitHub, testers, spicetify-cli }:
+
+buildGoModule rec {
+  pname = "spicetify-cli";
+  version = "2.27.2";
+
+  src = fetchFromGitHub {
+    owner = "spicetify";
+    repo = "spicetify-cli";
+    rev = "v${version}";
+    hash = "sha256-TT7ZPvpiiDAvvN2ec/qN4i/6XCxfeBTPLD3dCxVTKBY=";
+  };
+
+  vendorHash = "sha256-H2kSTsYiD9HResHes+7YxUyNcjtM0SLpDPUC0Y518VM=";
+
+  ldflags = [
+    "-s -w"
+    "-X 'main.version=${version}'"
+  ];
+
+  # used at runtime, but not installed by default
+  postInstall = ''
+    cp -r ${src}/jsHelper $out/bin/jsHelper
+    cp -r ${src}/CustomApps $out/bin/CustomApps
+    cp -r ${src}/Extensions $out/bin/Extensions
+    cp -r ${src}/Themes $out/bin/Themes
+  '';
+
+  doInstallCheck = true;
+  installCheckPhase = ''
+    $out/bin/spicetify-cli --help > /dev/null
+  '';
+
+  passthru.tests.version = testers.testVersion {
+    package = spicetify-cli;
+    command = "spicetify-cli -v";
+  };
+
+  meta = with lib; {
+    description = "Command-line tool to customize Spotify client";
+    homepage = "https://github.com/spicetify/spicetify-cli/";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ jonringer mdarocha ];
+    mainProgram = "spicetify-cli";
+  };
+}