xdg-user-dirs: migrate to by-name

1 files changed, 29 insertions, 0 deletions

diff --git a/pkgs/by-name/xd/xdg-user-dirs/package.nix b/pkgs/by-name/xd/xdg-user-dirs/package.nix
new file mode 100644
index 000000000000..be2afce19b71
--- /dev/null
+++ b/pkgs/by-name/xd/xdg-user-dirs/package.nix
@@ -0,0 +1,29 @@
+{ lib, stdenv, fetchurl, libxslt, docbook_xsl, gettext, libiconv, makeWrapper }:
+
+stdenv.mkDerivation rec {
+  pname = "xdg-user-dirs";
+  version = "0.18";
+
+  src = fetchurl {
+    url = "https://user-dirs.freedesktop.org/releases/xdg-user-dirs-${version}.tar.gz";
+    sha256 = "sha256-7G8G10lc26N6cyA5+bXhV4vLKWV2/eDaQO2y9SIg3zw=";
+  };
+
+  buildInputs = lib.optionals stdenv.isDarwin [ libiconv ];
+
+  nativeBuildInputs = [ makeWrapper libxslt docbook_xsl ] ++ lib.optionals stdenv.isDarwin [ gettext ];
+
+  preFixup = ''
+    # fallback values need to be last
+    wrapProgram "$out/bin/xdg-user-dirs-update" \
+      --suffix XDG_CONFIG_DIRS : "$out/etc/xdg"
+  '';
+
+  meta = with lib; {
+    homepage = "http://freedesktop.org/wiki/Software/xdg-user-dirs";
+    description = "A tool to help manage well known user directories like the desktop folder and the music folder";
+    license = licenses.gpl2;
+    maintainers = with maintainers; [ donovanglover ];
+    platforms = platforms.unix;
+  };
+}