git-cinnabar: use `finalAttrs` pattern

1 files changed, 37 insertions, 16 deletions

diff --git a/pkgs/applications/version-management/git-cinnabar/default.nix b/pkgs/applications/version-management/git-cinnabar/default.nix
index 92ba4bd81d1c..ca6a0165f1d0 100644
--- a/pkgs/applications/version-management/git-cinnabar/default.nix
+++ b/pkgs/applications/version-management/git-cinnabar/default.nix
@@ -1,29 +1,48 @@
-{ stdenv, lib, fetchFromGitHub, cargo, pkg-config, rustPlatform
-, bzip2, curl, zlib, zstd, libiconv, CoreServices
+{ stdenv
+, lib
+, fetchFromGitHub
+, cargo
+, pkg-config
+, rustPlatform
+, bzip2
+, curl
+, zlib
+, zstd
+, libiconv
+, CoreServices
 }:
 
-stdenv.mkDerivation rec {
+stdenv.mkDerivation (finalAttrs: {
   pname = "git-cinnabar";
   version = "0.6.2";
 
   src = fetchFromGitHub {
     owner = "glandium";
     repo = "git-cinnabar";
-    rev = version;
-    sha256 = "1Y4zd4rYNRatemDXRMkQQwBJdkfOGfDWk9QBvJOgi7s=";
+    rev = finalAttrs.version;
+    hash = "sha256-1Y4zd4rYNRatemDXRMkQQwBJdkfOGfDWk9QBvJOgi7s=";
     fetchSubmodules = true;
   };
 
   nativeBuildInputs = [
-    pkg-config rustPlatform.cargoSetupHook cargo
+    cargo
+    pkg-config
+    rustPlatform.cargoSetupHook
   ];
 
-  buildInputs = [ bzip2 curl zlib zstd ]
-    ++ lib.optionals stdenv.isDarwin [ libiconv CoreServices ];
+  buildInputs = [
+    bzip2
+    curl
+    zlib
+    zstd
+  ] ++ lib.optionals stdenv.isDarwin [
+    libiconv
+    CoreServices
+  ];
 
   cargoDeps = rustPlatform.fetchCargoTarball {
-    inherit src;
-    sha256 = "p85AS2DukUzEbW9UGYmiF3hpnZvPrZ2sRaeA9dU8j/8=";
+    inherit (finalAttrs) src;
+    hash = "sha256-p85AS2DukUzEbW9UGYmiF3hpnZvPrZ2sRaeA9dU8j/8=";
   };
 
   ZSTD_SYS_USE_PKG_CONFIG = true;
@@ -32,17 +51,19 @@ stdenv.mkDerivation rec {
 
   installPhase = ''
     runHook preInstall
+
     mkdir -p $out/bin
     install -v target/release/git-cinnabar $out/bin
     ln -sv git-cinnabar $out/bin/git-remote-hg
+
     runHook postInstall
   '';
 
-  meta = with lib; {
-    homepage = "https://github.com/glandium/git-cinnabar";
+  meta = {
     description = "git remote helper to interact with mercurial repositories";
-    license = licenses.gpl2Only;
-    maintainers = with maintainers; [ qyliss ];
-    platforms = platforms.all;
+    homepage = "https://github.com/glandium/git-cinnabar";
+    license = lib.licenses.gpl2Only;
+    maintainers = with lib.maintainers; [ qyliss ];
+    platforms = lib.platforms.all;
   };
-}
+})