Adding Firefox 3.5b4

svn path=/nixpkgs/trunk/; revision=15451

2 files changed, 183 insertions, 0 deletions

diff --git a/pkgs/applications/networking/browsers/firefox-3/3.5.nix b/pkgs/applications/networking/browsers/firefox-3/3.5.nix
new file mode 100644
index 000000000000..336a631e1e28
--- /dev/null
+++ b/pkgs/applications/networking/browsers/firefox-3/3.5.nix
@@ -0,0 +1,86 @@
+{ stdenv, fetchurl, pkgconfig, gtk, pango, perl, python, zip, libIDL
+, libjpeg, zlib, cairo, dbus, dbus_glib, bzip2
+, freetype, fontconfig, xulrunner, alsaLib, autoconf
+
+, # If you want the resulting program to call itself "Firefox" instead
+  # of "Deer Park", enable this option.  However, those binaries may
+  # not be distributed without permission from the Mozilla Foundation,
+  # see http://www.mozilla.org/foundation/trademarks/.
+  enableOfficialBranding ? false
+    
+}:
+
+let version = "3.5b4"; in
+
+stdenv.mkDerivation {
+  name = "firefox-${version}";
+
+  src = fetchurl {
+    url = "ftp://ftp.mozilla.org/pub/firefox/releases/${version}/source/firefox-${version}-source.tar.bz2";
+    sha256 = "0pfrcqbsa88p6nfqx7xhlr603ycwf5lnfmwcdd5abl7xipxg4lxn";
+  };
+
+  buildInputs = [
+    pkgconfig gtk perl zip libIDL libjpeg zlib cairo bzip2
+    python dbus dbus_glib pango freetype fontconfig alsaLib
+    autoconf
+  ];
+
+  propagatedBuildInputs = [xulrunner];
+
+  preConfigure = ''
+    export PREFIX=$out
+    export LIBXUL_DIST=$out
+    autoconf
+    cd js/src
+    autoconf
+    cd ../..
+  '';
+
+  preBuild = ''
+    cd nsprpub
+    autoconf 
+    ./configure
+    make
+    cd ..
+  '';
+
+  configureFlags = [
+    "--enable-application=browser"
+    "--enable-optimize"
+    "--disable-debug"
+    "--enable-strip"
+    "--with-system-jpeg"
+    "--with-system-zlib"
+    "--with-system-bz2"
+    # "--with-system-png" # <-- "--with-system-png won't work because the system's libpng doesn't have APNG support"
+    "--enable-system-cairo"
+    #"--enable-system-sqlite" # <-- this seems to be discouraged
+    "--disable-crashreporter"
+    "--with-libxul-sdk=${xulrunner}/lib/xulrunner-devel-${xulrunner.version}"
+  ];
+
+  postInstall = ''
+    # Strip some more stuff.
+    strip -S $out/lib/*/* || true
+
+    libDir=$(cd $out/lib && ls -d firefox-[0-9]*)
+    test -n "$libDir"
+    
+    ln -s ${xulrunner}/lib/xulrunner-${xulrunner.version} $out/lib/$libDir/xulrunner
+
+    # Register extensions etc. !!! is this needed anymore?
+    echo "running firefox -register..."
+    $out/bin/firefox -register
+  ''; # */
+
+  meta = {
+    description = "Mozilla Firefox - the browser, reloaded";
+    homepage = http://www.mozilla.com/en-US/firefox/;
+  };
+
+  passthru = {
+    inherit gtk;
+    isFirefox3Like = true;
+  };
+}
diff --git a/pkgs/applications/networking/browsers/firefox-3/xulrunner-3.5.nix b/pkgs/applications/networking/browsers/firefox-3/xulrunner-3.5.nix
new file mode 100644
index 000000000000..1192c01bfb80
--- /dev/null
+++ b/pkgs/applications/networking/browsers/firefox-3/xulrunner-3.5.nix
@@ -0,0 +1,97 @@
+{ stdenv, fetchurl, pkgconfig, gtk, pango, perl, python, zip, libIDL
+, libjpeg, libpng, zlib, cairo, dbus, dbus_glib, bzip2, xlibs
+, freetype, fontconfig, file, alsaLib, autoconf
+
+, # If you want the resulting program to call itself "Firefox" instead
+  # of "Deer Park", enable this option.  However, those binaries may
+  # not be distributed without permission from the Mozilla Foundation,
+  # see http://www.mozilla.org/foundation/trademarks/.
+  enableOfficialBranding ? false
+}:
+
+let
+
+  version = "1.9.1b4"; # this attribute is used by other packages
+  ffversion = "3.5b4";
+
+in  
+
+stdenv.mkDerivation {
+  name = "xulrunner-${version}";
+
+  src = fetchurl {
+    url = "ftp://ftp.mozilla.org/pub/firefox/releases/${ffversion}/source/firefox-${ffversion}-source.tar.bz2";
+    sha256 = "0pfrcqbsa88p6nfqx7xhlr603ycwf5lnfmwcdd5abl7xipxg4lxn";
+  };
+
+  buildInputs = [
+    pkgconfig gtk perl zip libIDL libjpeg libpng zlib cairo bzip2
+    python dbus dbus_glib pango freetype fontconfig
+    xlibs.libXi xlibs.libX11 xlibs.libXrender xlibs.libXft xlibs.libXt
+    file alsaLib autoconf
+  ];
+
+  preConfigure = ''
+    export PREFIX=$out
+    export LIBXUL_DIST=$out
+    autoconf
+    cd js/src
+    autoconf
+    cd ../..
+  '';
+
+  configureFlags = [
+    "--enable-application=xulrunner"
+    "--disable-javaxpcom"
+    "--enable-optimize"
+    "--disable-debug"
+    "--enable-strip"
+    "--with-system-jpeg"
+    "--with-system-zlib"
+    "--with-system-bz2"
+    # "--with-system-png" # <-- "--with-system-png won't work because the system's libpng doesn't have APNG support"
+    "--enable-system-cairo"
+    #"--enable-system-sqlite" # <-- this seems to be discouraged
+    "--disable-crashreporter"
+  ];
+
+  installFlags = [
+    "SKIP_GRE_REGISTRATION=1"
+  ];
+
+  postInstall = ''
+    export dontPatchELF=1;
+
+    # Strip some more stuff
+    strip -S $out/lib/*/* || true
+
+    # Fix some references to /bin paths in the Firefox shell script.
+    substituteInPlace $out/bin/xulrunner \
+        --replace /bin/pwd "$(type -tP pwd)" \
+        --replace /bin/ls "$(type -tP ls)"
+    
+    # Fix run-mozilla.sh search
+    libDir=$(cd $out/lib && ls -d xulrunner-[0-9]*)
+    echo libDir: $libDir
+    test -n "$libDir"
+    cd $out/bin
+    mv xulrunner ../lib/$libDir/
+
+    for i in $out/lib/$libDir/*; do 
+        file $i;
+        if file $i | grep executable &>/dev/null; then 
+	    ln -s $i $out/bin
+        fi;
+    done;
+    rm $out/bin/run-mozilla.sh || true
+  ''; # */
+
+  meta = {
+    description = "Mozilla Firefox XUL runner";
+    homepage = http://www.mozilla.com/en-US/firefox/;
+  };
+
+  passthru = { inherit gtk version; };
+}
+
+