oranda: init at 0.0.3

1 files changed, 58 insertions, 0 deletions

diff --git a/pkgs/applications/misc/oranda/default.nix b/pkgs/applications/misc/oranda/default.nix
new file mode 100644
index 000000000000..9bc9d68fb44e
--- /dev/null
+++ b/pkgs/applications/misc/oranda/default.nix
@@ -0,0 +1,58 @@
+{ lib
+, rustPlatform
+, fetchFromGitHub
+, pkg-config
+, bzip2
+, oniguruma
+, openssl
+, xz
+, zstd
+, stdenv
+, darwin
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "oranda";
+  version = "0.0.3";
+
+  src = fetchFromGitHub {
+    owner = "axodotdev";
+    repo = "oranda";
+    rev = "v${version}";
+    hash = "sha256-MT0uwLDrofCFyyYiUOogF2kNs6EPS1qxPz0gdK+Tkkg=";
+  };
+
+  cargoHash = "sha256-dAnZc1VvOubfn7mnpttaB6FotN3Xc+t9Qn0n5uzv1Qg=";
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    bzip2
+    oniguruma
+    openssl
+    xz
+    zstd
+  ] ++ lib.optionals stdenv.isDarwin [
+    darwin.apple_sdk.frameworks.Security
+  ];
+
+  # requires internet access
+  checkFlags = [
+    "--skip=build"
+  ];
+
+  env = {
+    RUSTONIG_SYSTEM_LIBONIG = true;
+    ZSTD_SYS_USE_PKG_CONFIG = true;
+  };
+
+  meta = with lib; {
+    description = "Generate beautiful landing pages for your developer tools";
+    homepage = "https://github.com/axodotdev/oranda";
+    changelog = "https://github.com/axodotdev/oranda/blob/${src.rev}/CHANGELOG.md";
+    license = with licenses; [ asl20 mit ];
+    maintainers = with maintainers; [ figsoda ];
+  };
+}