Merge branch 'staging-next' into staging

1 files changed, 69 insertions, 0 deletions

diff --git a/pkgs/applications/graphics/drawing/default.nix b/pkgs/applications/graphics/drawing/default.nix
new file mode 100644
index 000000000000..67fa5da398bc
--- /dev/null
+++ b/pkgs/applications/graphics/drawing/default.nix
@@ -0,0 +1,69 @@
+{ lib
+, fetchFromGitHub
+, meson
+, ninja
+, pkgconfig
+, python3
+, gtk3
+, appstream-glib
+, desktop-file-utils
+, gobject-introspection
+, wrapGAppsHook
+, glib
+, gdk-pixbuf
+, pango
+, gettext
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "drawing";
+  version = "0.4.11";
+
+  format = "other";
+  
+  src = fetchFromGitHub {
+    owner = "maoschanz";
+    repo = pname;
+    rev = version;
+    sha256 = "00c1h6jns11rmsg35gy40fb6ahvik80wpbm2133bjcqxfwwnlal6";
+  };
+
+  nativeBuildInputs = [
+    appstream-glib
+    desktop-file-utils
+    gobject-introspection
+    meson
+    ninja
+    pkgconfig
+    wrapGAppsHook
+    glib
+    gettext
+  ];
+
+  buildInputs = [
+    glib
+    gtk3
+    gdk-pixbuf
+    pango
+  ];
+
+  propagatedBuildInputs = with python3.pkgs; [
+    pycairo
+    pygobject3
+  ];
+
+  postPatch = ''
+    chmod +x build-aux/meson/postinstall.py # patchShebangs requires executable file
+    patchShebangs build-aux/meson/postinstall.py
+  '';
+
+  strictDeps = false;
+
+  meta = with lib; {
+    description = "A free basic image editor, similar to Microsoft Paint, but aiming at the GNOME desktop";
+    homepage = "https://maoschanz.github.io/drawing/";
+    maintainers = with maintainers; [ mothsart ];
+    license = licenses.gpl3Plus;
+    platforms = platforms.linux;
+  };
+}