x16: move from commanderx16

Now they live under x16 attribute.
Since the old names are easier to use and remember, they should be kept as
non-removable aliases.

3 files changed, 0 insertions, 150 deletions

diff --git a/pkgs/applications/emulators/commanderx16/emulator.nix b/pkgs/applications/emulators/commanderx16/emulator.nix
deleted file mode 100644
index 9da865057739..000000000000
--- a/pkgs/applications/emulators/commanderx16/emulator.nix
+++ /dev/null
@@ -1,56 +0,0 @@
-{ lib
-, stdenv
-, fetchFromGitHub
-, SDL2
-, zlib
-}:
-
-stdenv.mkDerivation (finalAttrs: {
-  pname = "x16-emulator";
-  version = "44";
-
-  src = fetchFromGitHub {
-    owner = "X16Community";
-    repo = "x16-emulator";
-    rev = "r${finalAttrs.version}";
-    hash = "sha256-NDtfbhqGldxtvWQf/t6UnMRjI2DR7JYKbm2KFAMZhHY=";
-  };
-
-  postPatch = ''
-    substituteInPlace Makefile \
-      --replace '/bin/echo' 'echo'
-  '';
-
-  dontConfigure = true;
-
-  buildInputs = [
-    SDL2
-    zlib
-  ];
-
-  installPhase = ''
-    runHook preInstall
-
-    install -Dm 755 -t $out/bin/ x16emu
-    install -Dm 444 -t $out/share/doc/x16-emulator/ README.md
-
-    runHook postInstall
-  '';
-
-  passthru = {
-    # upstream project recommends emulator and rom to be synchronized; passing
-    # through the version is useful to ensure this
-    inherit (finalAttrs) version;
-  };
-
-  meta = {
-    homepage = "https://cx16forum.com/";
-    description = "The official emulator of CommanderX16 8-bit computer";
-    changelog = "https://github.com/X16Community/x16-emulator/blob/r${finalAttrs.version}/RELEASES.md";
-    license = lib.licenses.bsd2;
-    maintainers = with lib.maintainers; [ AndersonTorres ];
-    mainProgram = "x16emu";
-    inherit (SDL2.meta) platforms;
-    broken = stdenv.isAarch64; # ofborg fails to compile it
-  };
-})
diff --git a/pkgs/applications/emulators/commanderx16/rom.nix b/pkgs/applications/emulators/commanderx16/rom.nix
deleted file mode 100644
index c272faa706aa..000000000000
--- a/pkgs/applications/emulators/commanderx16/rom.nix
+++ /dev/null
@@ -1,57 +0,0 @@
-{ lib
-, stdenv
-, fetchFromGitHub
-, cc65
-, python3
-}:
-
-stdenv.mkDerivation (finalAttrs: {
-  pname = "x16-rom";
-  version = "44";
-
-  src = fetchFromGitHub {
-    owner = "X16Community";
-    repo = "x16-rom";
-    rev = "r${finalAttrs.version}";
-    hash = "sha256-x/U+8e869mkWZKmCiW2fZKGB9un2cFXNclemwxbAjLQ=";
-  };
-
-  nativeBuildInputs = [
-    cc65
-    python3
-  ];
-
-  postPatch = ''
-    patchShebangs findsymbols scripts/
-    substituteInPlace Makefile \
-    --replace '/bin/echo' 'echo'
-  '';
-
-  dontConfigure = true;
-
-  makeFlags = [ "PRERELEASE_VERSION=${finalAttrs.version}" ];
-
-  installPhase = ''
-    runHook preInstall
-
-    install -Dm 444 -t $out/share/x16-rom/ build/x16/rom.bin
-    install -Dm 444 -t $out/share/doc/x16-rom/ README.md
-
-    runHook postInstall
-  '';
-
-  passthru = {
-    # upstream project recommends emulator and rom to be synchronized; passing
-    # through the version is useful to ensure this
-    inherit (finalAttrs) version;
-  };
-
-  meta = {
-    homepage = "https://github.com/X16Community/x16-rom";
-    description = "ROM file for CommanderX16 8-bit computer";
-    license = lib.licenses.bsd2;
-    maintainers = with lib.maintainers; [ AndersonTorres ];
-    inherit (cc65.meta) platforms;
-    broken = stdenv.isDarwin && stdenv.isAarch64;
-  };
-})
diff --git a/pkgs/applications/emulators/commanderx16/run.nix b/pkgs/applications/emulators/commanderx16/run.nix
deleted file mode 100644
index 1f14fdb223c7..000000000000
--- a/pkgs/applications/emulators/commanderx16/run.nix
+++ /dev/null
@@ -1,37 +0,0 @@
-{ runtimeShell
-, symlinkJoin
-, writeTextFile
-}:
-
-{ emulator, rom }:
-
-assert emulator.version == rom.version;
-
-let
-  runScript = writeTextFile {
-    name = "run-x16";
-    text = ''
-      #!${runtimeShell}
-
-      defaultRom="${rom}/share/x16-rom/rom.bin"
-
-      exec "${emulator}/bin/x16emu" -rom $defaultRom "$@"
-    '';
-    executable = true;
-    destination = "/bin/run-x16";
-  };
-in
-symlinkJoin {
-  name = "run-x16-${emulator.version}";
-
-  paths = [
-    emulator
-    rom
-    runScript
-  ];
-}
-# TODO [ AndersonTorres ]:
-
-# 1. Parse the command line in order to allow the user to set an optional
-# rom-file
-# 2. generate runScript based on symlinkJoin (maybe a postBuild?)