mopidy: Move mopidy default.nix to mopidy.nix

This is in anticipation of a mopidyPackages set

1 files changed, 44 insertions, 0 deletions

diff --git a/pkgs/applications/audio/mopidy/mopidy.nix b/pkgs/applications/audio/mopidy/mopidy.nix
new file mode 100644
index 000000000000..66be35bfcc8f
--- /dev/null
+++ b/pkgs/applications/audio/mopidy/mopidy.nix
@@ -0,0 +1,44 @@
+{ stdenv, fetchFromGitHub, python3Packages, wrapGAppsHook
+, gst_all_1, glib-networking, gobject-introspection
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "mopidy";
+  version = "3.0.2";
+
+  src = fetchFromGitHub {
+    owner = "mopidy";
+    repo = "mopidy";
+    rev = "v${version}";
+    sha256 = "1n9lpgq0p112cjgsrc1cd6mnffk56y36g2c5skk9cqzw27qrkd15";
+  };
+
+  nativeBuildInputs = [ wrapGAppsHook ];
+
+  buildInputs = with gst_all_1; [
+    gst-plugins-base gst-plugins-good gst-plugins-ugly gst-plugins-bad
+    glib-networking gobject-introspection
+  ];
+
+  propagatedBuildInputs = with python3Packages; [
+    gst-python pygobject3 pykka tornado_4 requests setuptools
+  ] ++ stdenv.lib.optional (!stdenv.isDarwin) dbus-python;
+
+  # There are no tests
+  doCheck = false;
+
+  preFixup = ''
+    gappsWrapperArgs+=(--prefix GST_PLUGIN_SYSTEM_PATH : "$GST_PLUGIN_SYSTEM_PATH")
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = "https://www.mopidy.com/";
+    description = ''
+      An extensible music server that plays music from local disk, Spotify,
+      SoundCloud, Google Play Music, and more
+    '';
+    license = licenses.asl20;
+    maintainers = [ maintainers.fpletz ];
+    hydraPlatforms = [];
+  };
+}