Add 'nixpkgs/' from commit 'abf060725d7614bd3b9f96764262dfbc2f9c2199'

git-subtree-dir: nixpkgs
git-subtree-mainline: 4e31070265257dc67d120c27e0f75c2344fdfa9a
git-subtree-split: abf060725d7614bd3b9f96764262dfbc2f9c2199

1 files changed, 46 insertions, 0 deletions

diff --git a/nixpkgs/pkgs/tools/system/gptfdisk/default.nix b/nixpkgs/pkgs/tools/system/gptfdisk/default.nix
new file mode 100644
index 000000000000..25d60ffca5dc
--- /dev/null
+++ b/nixpkgs/pkgs/tools/system/gptfdisk/default.nix
@@ -0,0 +1,46 @@
+{ fetchurl, stdenv, libuuid, popt, icu, ncurses }:
+
+stdenv.mkDerivation rec {
+  name = "gptfdisk-${version}";
+  version = "1.0.4";
+
+  src = fetchurl {
+    # https://www.rodsbooks.com/gdisk/${name}.tar.gz also works, but the home
+    # page clearly implies a preference for using SourceForge's bandwidth:
+    url = "mirror://sourceforge/gptfdisk/${name}.tar.gz";
+    sha256 = "13d7gff4prl1nsdknjigmb7bbqhn79165n01v4y9mwbnd0d3jqxn";
+  };
+
+  postPatch = ''
+    patchShebangs gdisk_test.sh
+  '' + stdenv.lib.optionalString stdenv.isDarwin ''
+    substituteInPlace Makefile.mac --replace \
+      "-mmacosx-version-min=10.4" "-mmacosx-version-min=10.6"
+    substituteInPlace Makefile.mac --replace \
+      " -arch i386" ""
+    substituteInPlace Makefile.mac --replace \
+      " -I/opt/local/include -I /usr/local/include -I/opt/local/include" ""
+    substituteInPlace Makefile.mac --replace \
+      "/opt/local/lib/libncurses.a" "${ncurses.out}/lib/libncurses.dylib"
+  '';
+
+  buildPhase = stdenv.lib.optionalString stdenv.isDarwin "make -f Makefile.mac";
+  buildInputs = [ libuuid popt icu ncurses ];
+
+  installPhase = ''
+    mkdir -p $out/sbin
+    mkdir -p $out/share/man/man8
+    for prog in gdisk sgdisk fixparts cgdisk
+    do
+        install -v -m755 $prog $out/sbin
+        install -v -m644 $prog.8 $out/share/man/man8
+    done
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Set of text-mode partitioning tools for Globally Unique Identifier (GUID) Partition Table (GPT) disks";
+    license = licenses.gpl2;
+    homepage = https://www.rodsbooks.com/gdisk/;
+    platforms = platforms.all;
+  };
+}