Add 'nixpkgs/' from commit 'abf060725d7614bd3b9f96764262dfbc2f9c2199'

git-subtree-dir: nixpkgs
git-subtree-mainline: 4e31070265257dc67d120c27e0f75c2344fdfa9a
git-subtree-split: abf060725d7614bd3b9f96764262dfbc2f9c2199

1 files changed, 47 insertions, 0 deletions

diff --git a/nixpkgs/pkgs/tools/misc/heimdall/default.nix b/nixpkgs/pkgs/tools/misc/heimdall/default.nix
new file mode 100644
index 000000000000..9e21ab5e38ff
--- /dev/null
+++ b/nixpkgs/pkgs/tools/misc/heimdall/default.nix
@@ -0,0 +1,47 @@
+{ stdenv, fetchFromGitHub, cmake
+, zlib, libusb1
+, enableGUI ? false, qtbase ? null }:
+
+stdenv.mkDerivation rec {
+  name = "heimdall-${if enableGUI then "gui-" else ""}${version}";
+  version = "1.4.2";
+
+  src = fetchFromGitHub {
+    owner  = "Benjamin-Dobell";
+    repo   = "Heimdall";
+    rev    = "v${version}";
+    sha256 = "1ygn4snvcmi98rgldgxf5hwm7zzi1zcsihfvm6awf9s6mpcjzbqz";
+  };
+
+  buildInputs = [
+    zlib libusb1
+  ] ++ stdenv.lib.optional enableGUI qtbase;
+  nativeBuildInputs = [ cmake ];
+
+  cmakeFlags = [
+    "-DDISABLE_FRONTEND=${if enableGUI then "OFF" else "ON"}"
+  ];
+
+  preConfigure = ''
+    # Give ownership of the Galaxy S USB device to the logged in user.
+    substituteInPlace heimdall/60-heimdall.rules --replace 'MODE="0666"' 'TAG+="uaccess"'
+  '';
+
+  installPhase = ''
+    mkdir -p $out/{bin,share/doc/heimdall,lib/udev/rules.d}
+    install -m755 -t $out/bin                bin/*
+    install -m644 -t $out/lib/udev/rules.d   ../heimdall/60-heimdall.rules
+    install -m644 ../Linux/README   $out/share/doc/heimdall/README.linux
+    install -m644 ../OSX/README.txt $out/share/doc/heimdall/README.osx
+  '';
+
+  enableParallelBuilding = true;
+
+  meta = with stdenv.lib; {
+    homepage    = http://www.glassechidna.com.au/products/heimdall/;
+    description = "A cross-platform tool suite to flash firmware onto Samsung Galaxy S devices";
+    license     = licenses.mit;
+    maintainers = with maintainers; [ peterhoeg ];
+    platforms   = platforms.unix;
+  };
+}