Add 'nixpkgs/' from commit 'abf060725d7614bd3b9f96764262dfbc2f9c2199'

git-subtree-dir: nixpkgs
git-subtree-mainline: 4e31070265257dc67d120c27e0f75c2344fdfa9a
git-subtree-split: abf060725d7614bd3b9f96764262dfbc2f9c2199

1 files changed, 51 insertions, 0 deletions

diff --git a/nixpkgs/pkgs/development/libraries/libvmi/default.nix b/nixpkgs/pkgs/development/libraries/libvmi/default.nix
new file mode 100644
index 000000000000..44b2a81b2d3c
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/libvmi/default.nix
@@ -0,0 +1,51 @@
+{ stdenv,
+  fetchFromGitHub,
+  autoreconfHook,
+  bison,
+  flex,
+  glib,
+  pkgconfig,
+  json_c,
+  xen,
+  libvirt,
+  xenSupport ? true }:
+
+with stdenv.lib;
+
+stdenv.mkDerivation rec {
+  name = "libvmi-${version}";
+  version = "0.12.0";
+  libVersion = "0.0.12";
+
+  src = fetchFromGitHub {
+    owner = "libvmi";
+    repo = "libvmi";
+    rev = "v${version}";
+    sha256 = "0wbi2nasb1gbci6cq23g6kq7i10rwi1y7r44rl03icr5prqjpdyv";
+  };
+
+  buildInputs = [ glib libvirt json_c ] ++ (optional xenSupport xen);
+  nativeBuildInputs = [ autoreconfHook bison flex pkgconfig ];
+
+  configureFlags = optional (!xenSupport) "--disable-xen";
+
+  # libvmi uses dlopen() for the xen libraries, however autoPatchelfHook doesn't work here
+  postFixup = optionalString xenSupport ''
+    libvmi="$out/lib/libvmi.so.${libVersion}"
+    oldrpath=$(patchelf --print-rpath "$libvmi")
+    patchelf --set-rpath "$oldrpath:${makeLibraryPath [ xen ]}" "$libvmi"
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = "http://libvmi.com/";
+    description = "A C library for virtual machine introspection";
+    longDescription = ''
+      LibVMI is a C library with Python bindings that makes it easy to monitor the low-level
+      details of a running virtual machine by viewing its memory, trapping on hardware events,
+      and accessing the vCPU registers.
+    '';
+    license = with licenses; [ gpl3 lgpl3 ];
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ lschuermann ];
+  };
+}