Add 'nixpkgs/' from commit 'abf060725d7614bd3b9f96764262dfbc2f9c2199'

git-subtree-dir: nixpkgs
git-subtree-mainline: 4e31070265257dc67d120c27e0f75c2344fdfa9a
git-subtree-split: abf060725d7614bd3b9f96764262dfbc2f9c2199

2 files changed, 64 insertions, 0 deletions

diff --git a/nixpkgs/pkgs/development/libraries/libui/default.nix b/nixpkgs/pkgs/development/libraries/libui/default.nix
new file mode 100644
index 000000000000..dcc406accbd7
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/libui/default.nix
@@ -0,0 +1,53 @@
+{ stdenv, fetchgit, cmake, pkgconfig, gtk3, cf-private, Cocoa }:
+
+let
+  shortName = "libui";
+  version   = "3.1a";
+  backend   = if stdenv.isDarwin then "darwin" else "unix";
+in
+
+stdenv.mkDerivation rec {
+  name = "${shortName}-${version}";
+  src  = fetchgit {
+    url    = "https://github.com/andlabs/libui.git";
+    rev    = "6ebdc96b93273c3cedf81159e7843025caa83058";
+    sha256 = "1lpbfa298c61aarlzgp7vghrmxg1274pzxh1j9isv8x758gk6mfn";
+  };
+
+  nativeBuildInputs = [ cmake pkgconfig ];
+  buildInputs = stdenv.lib.optional stdenv.isLinux gtk3
+    ++ stdenv.lib.optionals stdenv.isDarwin [ Cocoa cf-private /* For NSDefaultRunLoopMode */ ];
+
+  preConfigure = stdenv.lib.optionalString stdenv.isDarwin ''
+    sed -i 's/set(CMAKE_OSX_DEPLOYMENT_TARGET "10.8")//' ./CMakeLists.txt
+  '';
+
+  installPhase = ''
+    mkdir -p $out/{include,lib}
+    mkdir -p $out/lib/pkgconfig
+  '' + stdenv.lib.optionalString stdenv.isLinux ''
+    mv ./out/${shortName}.so.0 $out/lib/
+    ln -s $out/lib/${shortName}.so.0 $out/lib/${shortName}.so
+  '' + stdenv.lib.optionalString stdenv.isDarwin ''
+    mv ./out/${shortName}.A.dylib $out/lib/
+    ln -s $out/lib/${shortName}.A.dylib $out/lib/${shortName}.dylib
+  '' + ''
+    cp $src/ui.h $out/include
+    cp $src/ui_${backend}.h $out/include
+
+    cp ${./libui.pc} $out/lib/pkgconfig/${shortName}.pc
+    substituteInPlace $out/lib/pkgconfig/${shortName}.pc \
+      --subst-var-by out $out \
+      --subst-var-by version "${version}"
+  '';
+  postInstall = stdenv.lib.optionalString stdenv.isDarwin ''
+    install_name_tool -id $out/lib/${shortName}.A.dylib $out/lib/${shortName}.A.dylib
+  '';
+
+  meta = with stdenv.lib; {
+    homepage    = https://github.com/andlabs/libui;
+    description = "Simple and portable (but not inflexible) GUI library in C that uses the native GUI technologies of each platform it supports.";
+    license     = licenses.mit;
+    platforms   = platforms.unix;
+  };
+}
diff --git a/nixpkgs/pkgs/development/libraries/libui/libui.pc b/nixpkgs/pkgs/development/libraries/libui/libui.pc
new file mode 100644
index 000000000000..42ee86fb550f
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/libui/libui.pc
@@ -0,0 +1,11 @@
+prefix=@out@
+exec_prefix=${prefix}
+libdir=${exec_prefix}/lib
+includedir=${exec_prefix}/include
+
+Name: libui
+Description: Simple and portable (but not inflexible) GUI library
+Version: @version@
+
+Libs: -L${libdir} -lui
+Cflags: -I${includedir}