Add 'nixpkgs/' from commit 'abf060725d7614bd3b9f96764262dfbc2f9c2199'

git-subtree-dir: nixpkgs
git-subtree-mainline: 4e31070265257dc67d120c27e0f75c2344fdfa9a
git-subtree-split: abf060725d7614bd3b9f96764262dfbc2f9c2199

1 files changed, 43 insertions, 0 deletions

diff --git a/nixpkgs/pkgs/development/libraries/libcef/default.nix b/nixpkgs/pkgs/development/libraries/libcef/default.nix
new file mode 100644
index 000000000000..9e7d608b5124
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/libcef/default.nix
@@ -0,0 +1,43 @@
+{ stdenv, fetchurl, cmake, alsaLib, atk, cairo, cups, dbus, expat, fontconfig
+, GConf, gdk_pixbuf, glib, gtk2, libX11, libxcb, libXcomposite, libXcursor
+, libXdamage, libXext, libXfixes, libXi, libXrandr, libXrender, libXScrnSaver
+, libXtst, nspr, nss, pango, libpulseaudio, systemd }:
+
+let
+  libPath =
+    stdenv.lib.makeLibraryPath [
+      alsaLib atk cairo cups dbus expat fontconfig GConf gdk_pixbuf glib gtk2
+      libX11 libxcb libXcomposite libXcursor libXdamage libXext libXfixes libXi
+      libXrandr libXrender libXScrnSaver libXtst nspr nss pango libpulseaudio
+      systemd
+    ];
+in
+stdenv.mkDerivation rec {
+  name = "cef-binary-${version}";
+  version = "3.3497.1833.g13f506f";
+  src = fetchurl {
+    url = "http://opensource.spotify.com/cefbuilds/cef_binary_${version}_linux64.tar.bz2";
+    sha256 = "02v22yx1ga2yxagjblzkfw0ax7zkrdpc959l1a15m8nah3y7xf9p";
+  };
+  nativeBuildInputs = [ cmake ];
+  makeFlags = "libcef_dll_wrapper";
+  dontStrip = true;
+  dontPatchELF = true;
+  installPhase = ''
+    mkdir -p $out/lib/ $out/share/cef/
+    cp libcef_dll_wrapper/libcef_dll_wrapper.a $out/lib/
+    cp ../Release/libcef.so $out/lib/
+    patchelf --set-rpath "${libPath}" $out/lib/libcef.so
+    cp ../Release/*.bin $out/share/cef/
+    cp -r ../Resources/* $out/share/cef/
+    cp -r ../include $out/
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Simple framework for embedding Chromium-based browsers in other applications";
+    homepage = http://opensource.spotify.com/cefbuilds/index.html;
+    maintainers = with maintainers; [ puffnfresh ];
+    license = licenses.bsd3;
+    platforms = with platforms; linux;
+  };
+}