Merge branch 'nixos-unstable' of https://github.com/NixOS/nixpkgs

Conflicts:
	nixpkgs/pkgs/applications/window-managers/sway/default.nix
	nixpkgs/pkgs/build-support/go/module.nix
	nixpkgs/pkgs/build-support/rust/build-rust-package/default.nix
	nixpkgs/pkgs/development/libraries/mesa/default.nix
	nixpkgs/pkgs/servers/dict/dictd-db.nix

Link: https://gitlab.freedesktop.org/xkeyboard-config/xkeyboard-config/-/issues/391

1 files changed, 67 insertions, 0 deletions

diff --git a/nixpkgs/pkgs/development/libraries/ctranslate2/default.nix b/nixpkgs/pkgs/development/libraries/ctranslate2/default.nix
new file mode 100644
index 000000000000..a4ebfb5c3de1
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/ctranslate2/default.nix
@@ -0,0 +1,67 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, cmake
+, darwin # Accelerate
+, llvmPackages # openmp
+, withMkl ? false, mkl
+# Enabling both withOneDNN and withOpenblas is broken
+# https://github.com/OpenNMT/CTranslate2/issues/1294
+, withOneDNN ? false, oneDNN
+, withOpenblas ? true, openblas
+, withRuy ? true
+}:
+
+let
+  cmakeBool = b: if b then "ON" else "OFF";
+in
+stdenv.mkDerivation rec {
+  pname = "ctranslate2";
+  version = "3.18.0";
+
+  src = fetchFromGitHub {
+    owner = "OpenNMT";
+    repo = "CTranslate2";
+    rev = "v${version}";
+    hash = "sha256-ipCUiCyWubKTUB0jDOsRN+DSg3S84hbj8Xum/2NsrKc=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  cmakeFlags = [
+    # https://opennmt.net/CTranslate2/installation.html#build-options
+    # https://github.com/OpenNMT/CTranslate2/blob/54810350e662ebdb01ecbf8e4a746f02aeff1dd7/python/tools/prepare_build_environment_linux.sh#L53
+    # https://github.com/OpenNMT/CTranslate2/blob/59d223abcc7e636c1c2956e62482bc3299cc7766/python/tools/prepare_build_environment_macos.sh#L12
+    "-DOPENMP_RUNTIME=COMP"
+    "-DWITH_DNNL=${cmakeBool withOneDNN}"
+    "-DWITH_OPENBLAS=${cmakeBool withOpenblas}"
+    "-DWITH_RUY=${cmakeBool withRuy}"
+    "-DWITH_MKL=${cmakeBool withMkl}"
+  ]
+  ++ lib.optional stdenv.isDarwin "-DWITH_ACCELERATE=ON";
+
+  buildInputs = lib.optionals withMkl [
+    mkl
+  ] ++ lib.optionals withOneDNN [
+    oneDNN
+  ] ++ lib.optionals withOpenblas [
+    openblas
+  ] ++ lib.optionals stdenv.isDarwin [
+    llvmPackages.openmp
+    darwin.apple_sdk.frameworks.Accelerate
+  ] ++ lib.optionals (stdenv.isDarwin && stdenv.isx86_64) [
+    darwin.apple_sdk.frameworks.CoreGraphics
+    darwin.apple_sdk.frameworks.CoreVideo
+  ];
+
+  meta = with lib; {
+    description = "Fast inference engine for Transformer models";
+    homepage = "https://github.com/OpenNMT/CTranslate2";
+    changelog = "https://github.com/OpenNMT/CTranslate2/blob/${src.rev}/CHANGELOG.md";
+    license = licenses.mit;
+    maintainers = with maintainers; [ hexa misuzu ];
+  };
+}