Add 'nixpkgs/' from commit 'abf060725d7614bd3b9f96764262dfbc2f9c2199'

git-subtree-dir: nixpkgs
git-subtree-mainline: 4e31070265257dc67d120c27e0f75c2344fdfa9a
git-subtree-split: abf060725d7614bd3b9f96764262dfbc2f9c2199

5 files changed, 248 insertions, 0 deletions

diff --git a/nixpkgs/pkgs/development/libraries/aqbanking/default.nix b/nixpkgs/pkgs/development/libraries/aqbanking/default.nix
new file mode 100644
index 000000000000..b26291469e75
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/aqbanking/default.nix
@@ -0,0 +1,40 @@
+{ stdenv, fetchurl, gmp, gwenhywfar, libtool, libxml2, libxslt
+, pkgconfig, gettext, xmlsec, zlib
+}:
+
+let
+  inherit ((import ./sources.nix).aqbanking) sha256 releaseId version;
+in stdenv.mkDerivation rec {
+  name = "aqbanking-${version}";
+  inherit version;
+
+  src = let
+    qstring = "package=03&release=${releaseId}&file=02";
+    mkURLs = map (base: "${base}/sites/download/download.php?${qstring}");
+  in fetchurl {
+    name = "${name}.tar.gz";
+    urls = mkURLs [ "http://www.aquamaniac.de" "http://www2.aquamaniac.de" ];
+    inherit sha256;
+  };
+
+  postPatch = ''
+    sed -i -e '/^aqbanking_plugindir=/ {
+      c aqbanking_plugindir="\''${libdir}/gwenhywfar/plugins"
+    }' configure
+  '';
+
+  buildInputs = [ gmp gwenhywfar libtool libxml2 libxslt xmlsec zlib ];
+
+  nativeBuildInputs = [ pkgconfig gettext ];
+
+  configureFlags = [ "--with-gwen-dir=${gwenhywfar}" ];
+
+  meta = with stdenv.lib; {
+    description = "An interface to banking tasks, file formats and country information";
+    homepage = http://www2.aquamaniac.de/sites/download/packages.php?package=03&showall=1;
+    hydraPlatforms = [];
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ goibhniu ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/nixpkgs/pkgs/development/libraries/aqbanking/gwenhywfar.nix b/nixpkgs/pkgs/development/libraries/aqbanking/gwenhywfar.nix
new file mode 100644
index 000000000000..bb337e471cfc
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/aqbanking/gwenhywfar.nix
@@ -0,0 +1,71 @@
+{ stdenv, fetchurl, gnutls, openssl, libgcrypt, libgpgerror, pkgconfig, gettext
+, which
+
+# GUI support
+, gtk2, gtk3, qt5
+
+, pluginSearchPaths ? [
+    "/run/current-system/sw/lib/gwenhywfar/plugins"
+    ".nix-profile/lib/gwenhywfar/plugins"
+  ]
+}:
+
+let
+  inherit ((import ./sources.nix).gwenhywfar) sha256 releaseId version;
+in stdenv.mkDerivation rec {
+  name = "gwenhywfar-${version}";
+  inherit version;
+
+  src = let
+    qstring = "package=01&release=${releaseId}&file=02";
+    mkURLs = map (base: "${base}/sites/download/download.php?${qstring}");
+  in fetchurl {
+    name = "${name}.tar.gz";
+    urls = mkURLs [ "http://www.aquamaniac.de" "http://www2.aquamaniac.de" ];
+    inherit sha256;
+  };
+
+  configureFlags = [
+    "--with-openssl-includes=${openssl.dev}/include"
+    "--with-openssl-libs=${openssl.out}/lib"
+  ];
+
+  preConfigure = ''
+    configureFlagsArray+=("--with-guis=gtk2 gtk3 qt5")
+  '';
+
+  postPatch = let
+    isRelative = path: builtins.substring 0 1 path != "/";
+    mkSearchPath = path: ''
+      p; g; s,\<PLUGINDIR\>,"${path}",g;
+    '' + stdenv.lib.optionalString (isRelative path) ''
+      s/AddPath(\(.*\));/AddRelPath(\1, GWEN_PathManager_RelModeHome);/g
+    '';
+
+  in ''
+    sed -i -e '/GWEN_PathManager_DefinePath.*GWEN_PM_PLUGINDIR/,/^#endif/ {
+      /^#if/,/^#endif/ {
+        H; /^#endif/ {
+          ${stdenv.lib.concatMapStrings mkSearchPath pluginSearchPaths}
+        }
+      }
+    }' src/gwenhywfar.c
+
+    # Strip off the effective SO version from the path so that for example
+    # "lib/gwenhywfar/plugins/60" becomes just "lib/gwenhywfar/plugins".
+    sed -i -e '/^gwenhywfar_plugindir=/s,/\''${GWENHYWFAR_SO_EFFECTIVE},,' \
+      configure
+  '';
+
+  nativeBuildInputs = [ pkgconfig gettext which ];
+
+  buildInputs = [ gtk2 gtk3 qt5.qtbase gnutls openssl libgcrypt libgpgerror ];
+
+  meta = with stdenv.lib; {
+    description = "OS abstraction functions used by aqbanking and related tools";
+    homepage = http://www2.aquamaniac.de/sites/download/packages.php?package=01&showall=1;
+    license = licenses.lgpl21;
+    maintainers = with maintainers; [ goibhniu ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/nixpkgs/pkgs/development/libraries/aqbanking/libchipcard.nix b/nixpkgs/pkgs/development/libraries/aqbanking/libchipcard.nix
new file mode 100644
index 000000000000..9a0b70e0d97f
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/aqbanking/libchipcard.nix
@@ -0,0 +1,33 @@
+{ stdenv, fetchurl, pkgconfig, gwenhywfar, pcsclite, zlib }:
+
+let
+  inherit ((import ./sources.nix).libchipcard) sha256 releaseId version;
+in stdenv.mkDerivation rec {
+  name = "libchipcard-${version}";
+  inherit version;
+
+  src = let
+    qstring = "package=02&release=${releaseId}&file=01";
+    mkURLs = map (base: "${base}/sites/download/download.php?${qstring}");
+  in fetchurl {
+    name = "${name}.tar.gz";
+    urls = mkURLs [ "http://www.aquamaniac.de" "http://www2.aquamaniac.de" ];
+    inherit sha256;
+  };
+
+  nativeBuildInputs = [ pkgconfig ];
+
+  buildInputs = [ gwenhywfar pcsclite zlib ];
+
+  makeFlags = [ "crypttokenplugindir=$(out)/lib/gwenhywfar/plugins/ct" ];
+
+  configureFlags = [ "--with-gwen-dir=${gwenhywfar}" ];
+
+  meta = with stdenv.lib; {
+    description = "Library for access to chipcards";
+    homepage = http://www2.aquamaniac.de/sites/download/packages.php?package=02&showall=1;
+    license = licenses.lgpl21;
+    maintainers = with maintainers; [ aszlig ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/nixpkgs/pkgs/development/libraries/aqbanking/sources.nix b/nixpkgs/pkgs/development/libraries/aqbanking/sources.nix
new file mode 100644
index 000000000000..884543d282a7
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/aqbanking/sources.nix
@@ -0,0 +1,12 @@
+# This file is autogenerated from update.sh in the same directory.
+{
+  gwenhywfar.version = "4.20.0";
+  gwenhywfar.sha256 = "1c0g3f8jk6j693774ifslx2ds4ksabgbbalhhm9gk20kpamxm22s";
+  gwenhywfar.releaseId = "208";
+  libchipcard.version = "5.0.4";
+  libchipcard.sha256 = "0fj2h39ll4kiv28ch8qgzdbdbnzs8gl812qnm660bw89rynpjnnj";
+  libchipcard.releaseId = "200";
+  aqbanking.version = "5.7.8";
+  aqbanking.sha256 = "0s67mysskbiw1h1p0np4ph4351r7wq3nc873vylam7lsqi66xy0n";
+  aqbanking.releaseId = "217";
+}
diff --git a/nixpkgs/pkgs/development/libraries/aqbanking/update.sh b/nixpkgs/pkgs/development/libraries/aqbanking/update.sh
new file mode 100755
index 000000000000..8929e8bc6eb4
--- /dev/null
+++ b/nixpkgs/pkgs/development/libraries/aqbanking/update.sh
@@ -0,0 +1,92 @@
+#!/bin/sh -e
+basedir="$(cd "$(dirname "$0")" && pwd)"
+
+getCurrentVersions() {
+    [ -e "$basedir/sources.nix" ] || return 0
+    (cd "$basedir" && nix-instantiate --eval --strict -E '
+    toString ((import ../../../../lib).mapAttrsToList
+        (name: info: "${name}:${info.version}!${info.sha256}!${info.releaseId}")
+        (import ./sources.nix))
+    ' | tr -d '"')
+}
+
+currentVersions="$(getCurrentVersions)"
+
+getLastestVersion() {
+    local baseurl="https://www.aquamaniac.de"
+    local pkglist="sites/download/packages.php?package=$1&showall=1"
+    local url="$baseurl/$pkglist"
+    local reVersion='[0-9]+(\.[0-9]+)+' # Only release versions, no betas!
+    local reHref='href=".*release=([0-9]+).*dummy=[^0-9]*('"$reVersion"')\.tar'
+    local reFull='s/^.*<a\>.*\<'"$reHref"'.*/\2!\1/p'
+    curl -s "$url" | sed -nre "$reFull" | sort -V -k 1,1 | tail -n1
+}
+
+getEntry() {
+    local name="$1"
+    for entry in $currentVersions; do
+        if [ "${entry%%:*}" = "$name" ]; then
+            echo "${entry#*:}"
+            return 0
+        fi
+    done
+    return 1
+}
+
+prefetchNew() {
+    local name="$1"
+    local version="$2"
+    local package="$3"
+    local releaseId="$4"
+
+    local url="http://www.aquamaniac.de/sites/download/download.php"
+    local qstring="package=$package&release=$releaseId&file=01";
+
+    nix-prefetch-url --name "$name-$version.tar.gz" "$url?$qstring"
+}
+
+processPackage() {
+    local name="$1"
+    local package="$2"
+
+    local latest="$(getLastestVersion "$package")"
+    local current="$(getEntry "$name")"
+    local currentTail="${current#*!}"
+
+    local currentVersion="${current%%!*}"
+    local currentSha256="${currentTail%%!*}"
+    local currentReleaseId="${current##*!}"
+
+    local latestVersion="${latest%%!*}"
+    local latestReleaseId="${latest##*!}"
+
+    if [ "$latestVersion" = "$currentVersion" -a \
+         "$latestReleaseId" = "$currentReleaseId" ]; then
+        echo "  $name.version = \"$currentVersion\";"
+        echo "  $name.sha256 = \"$currentSha256\";"
+        echo "  $name.releaseId = \"$currentReleaseId\";"
+        return 0
+    fi
+
+    local latestSha256="$(
+        prefetchNew "$name" "$latestVersion" "$package" "$latestReleaseId"
+    )"
+
+    echo "  $name.version = \"$latestVersion\";"
+    echo "  $name.sha256 = \"$latestSha256\";"
+    echo "  $name.releaseId = \"$latestReleaseId\";"
+    return 0
+}
+
+generateNewSources() {
+    echo "# This file is autogenerated from update.sh in the same directory."
+    echo "{"
+    for package in gwenhywfar:01 libchipcard:02 aqbanking:03; do
+        processPackage "${package%%:*}" "${package##*:}"
+    done
+    echo "}"
+}
+
+if newSources="$(generateNewSources)"; then
+    echo "$newSources" > "$basedir/sources.nix"
+fi