Add 'nixpkgs/' from commit 'abf060725d7614bd3b9f96764262dfbc2f9c2199'

git-subtree-dir: nixpkgs
git-subtree-mainline: 4e31070265257dc67d120c27e0f75c2344fdfa9a
git-subtree-split: abf060725d7614bd3b9f96764262dfbc2f9c2199

1 files changed, 61 insertions, 0 deletions

diff --git a/nixpkgs/pkgs/development/idris-modules/build-idris-package.nix b/nixpkgs/pkgs/development/idris-modules/build-idris-package.nix
new file mode 100644
index 000000000000..5e1288685a7e
--- /dev/null
+++ b/nixpkgs/pkgs/development/idris-modules/build-idris-package.nix
@@ -0,0 +1,61 @@
+# Build an idris package
+{ stdenv, lib, idrisPackages, gmp }:
+  { idrisDeps ? []
+  , noPrelude ? false
+  , noBase ? false
+  , name
+  , version
+  , ipkgName ? name
+  , extraBuildInputs ? []
+  , ...
+  }@attrs:
+let
+  allIdrisDeps = idrisDeps
+    ++ lib.optional (!noPrelude) idrisPackages.prelude
+    ++ lib.optional (!noBase) idrisPackages.base;
+  idris-with-packages = idrisPackages.with-packages allIdrisDeps;
+  newAttrs = builtins.removeAttrs attrs [
+    "idrisDeps" "noPrelude" "noBase"
+    "name" "version" "ipkgName" "extraBuildInputs"
+  ] // {
+    meta = attrs.meta // {
+      platforms = attrs.meta.platforms or idrisPackages.idris.meta.platforms;
+    };
+  };
+in
+stdenv.mkDerivation ({
+  name = "idris-${name}-${version}";
+
+  buildInputs = [ idris-with-packages gmp ] ++ extraBuildInputs;
+  propagatedBuildInputs = allIdrisDeps;
+
+  # Some packages use the style
+  # opts = -i ../../path/to/package
+  # rather than the declarative pkgs attribute so we have to rewrite the path.
+  postPatch = ''
+    runHook prePatch
+    sed -i ${ipkgName}.ipkg -e "/^opts/ s|-i \\.\\./|-i ${idris-with-packages}/libs/|g"
+  '';
+
+  buildPhase = ''
+    runHook preBuild
+    idris --build ${ipkgName}.ipkg
+    runHook postBuild
+  '';
+
+  checkPhase = ''
+    runHook preCheck
+    if grep -q tests ${ipkgName}.ipkg; then
+      idris --testpkg ${ipkgName}.ipkg
+    fi
+    runHook postCheck
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    idris --install ${ipkgName}.ipkg --ibcsubdir $out/libs
+    IDRIS_DOC_PATH=$out/doc idris --installdoc ${ipkgName}.ipkg || true
+    runHook postInstall
+  '';
+
+} // newAttrs)