Merge commit 'a343533bccc62400e8a9560423486a3b6c11a23b'

1 files changed, 60 insertions, 0 deletions

diff --git a/nixpkgs/pkgs/by-name/sy/symfony-cli/package.nix b/nixpkgs/pkgs/by-name/sy/symfony-cli/package.nix
new file mode 100644
index 000000000000..e316ae832231
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/sy/symfony-cli/package.nix
@@ -0,0 +1,60 @@
+{ buildGoModule
+, fetchFromGitHub
+, lib
+, nix-update-script
+, testers
+, symfony-cli
+, nssTools
+, makeBinaryWrapper
+}:
+
+buildGoModule rec {
+  pname = "symfony-cli";
+  version = "5.8.8";
+  vendorHash = "sha256-ACK0JCaS1MOCgUi2DMEjIcKf/nMCcrdDyIdioBZv7qw=";
+
+  src = fetchFromGitHub {
+    owner = "symfony-cli";
+    repo = "symfony-cli";
+    rev = "v${version}";
+    hash = "sha256-GdmFRGyp4s5G5RTEFKjcrY/OpaEVCgRhNVJbY1F8vk0=";
+  };
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.version=${version}"
+    "-X main.channel=stable"
+  ];
+
+  buildInputs = [ makeBinaryWrapper ];
+
+  postInstall = ''
+    mkdir $out/libexec
+    mv $out/bin/symfony-cli $out/libexec/symfony
+
+    makeBinaryWrapper $out/libexec/symfony $out/bin/symfony \
+      --prefix PATH : ${lib.makeBinPath [ nssTools ]}
+  '';
+
+  # Tests requires network access
+  doCheck = false;
+
+  passthru = {
+    updateScript = nix-update-script { };
+    tests.version = testers.testVersion {
+      inherit version;
+      package = symfony-cli;
+      command = "symfony version --no-ansi";
+    };
+  };
+
+  meta = {
+    changelog = "https://github.com/symfony-cli/symfony-cli/releases/tag/v${version}";
+    description = "Symfony CLI";
+    homepage = "https://github.com/symfony-cli/symfony-cli";
+    license = lib.licenses.agpl3Plus;
+    mainProgram = "symfony";
+    maintainers = with lib.maintainers; [ drupol ];
+  };
+}