Merge branch 'nixos-unstable-small' of https://github.com/NixOS/nixpkgs

3 files changed, 111 insertions, 2 deletions

diff --git a/nixpkgs/pkgs/by-name/ro/rofimoji/package.nix b/nixpkgs/pkgs/by-name/ro/rofimoji/package.nix
new file mode 100644
index 000000000000..56730c975fd7
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/ro/rofimoji/package.nix
@@ -0,0 +1,58 @@
+{ lib
+, python3Packages
+, fetchFromGitHub
+, installShellFiles
+
+, waylandSupport ? true
+, x11Support ? true
+
+, rofi
+, wl-clipboard
+, wtype
+, xdotool
+, xsel
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "rofimoji";
+  version = "6.2.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "fdw";
+    repo = "rofimoji";
+    rev = version;
+    hash = "sha256-9P9hXBEfq6sqCvb2SfPBNadEoXAdWF3cmcKGEOK+EHE=";
+  };
+
+  nativeBuildInputs = [
+    python3Packages.poetry-core
+    installShellFiles
+  ];
+
+  # `rofi` and the `waylandSupport` and `x11Support` dependencies
+  # contain binaries needed at runtime.
+  propagatedBuildInputs = [ python3Packages.configargparse rofi ]
+    ++ lib.optionals waylandSupport [ wl-clipboard wtype ]
+    ++ lib.optionals x11Support [ xdotool xsel ];
+
+  # The 'extractors' sub-module is used for development
+  # and has additional dependencies.
+  postPatch = ''
+    rm -rf extractors
+  '';
+
+  postInstall = ''
+    installManPage src/picker/docs/rofimoji.1
+  '';
+
+  meta = with lib; {
+    description = "A simple emoji and character picker for rofi";
+    mainProgram = "rofimoji";
+    homepage = "https://github.com/fdw/rofimoji";
+    changelog = "https://github.com/fdw/rofimoji/blob/${src.rev}/CHANGELOG.md";
+    license = licenses.mit;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ justinlovinger ];
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/ro/route-graph/package.nix b/nixpkgs/pkgs/by-name/ro/route-graph/package.nix
new file mode 100644
index 000000000000..7b5e20451a98
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/ro/route-graph/package.nix
@@ -0,0 +1,51 @@
+{ lib
+, fetchFromGitHub
+, graphviz
+, python3
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "route-graph";
+  version = "0.2.1";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "audiusGmbH";
+    repo = "route-graph";
+    rev = "refs/tags/${version}";
+    hash = "sha256-OOXLmHxWre5t4tysDXV23PTkyUG6Zcpanw0fVCOLFTM=";
+  };
+
+  pythonRelaxDeps = [
+    "typing-extensions"
+  ];
+
+  nativeBuildInputs = with python3.pkgs; [
+    poetry-core
+    pythonRelaxDepsHook
+  ];
+
+  propagatedBuildInputs = [
+    graphviz
+  ] ++ (with python3.pkgs; [
+    scapy
+    typer
+    typing-extensions
+  ] ++ typer.optional-dependencies.all);
+
+  # Project has no tests
+  doCheck = false;
+
+  pythonImportsCheck = [
+    "route_graph"
+  ];
+
+  meta = with lib; {
+    description = "CLI tool for creating graphs of routes";
+    homepage = "https://github.com/audiusGmbH/route-graph";
+    changelog = "https://github.com/audiusGmbH/route-graph/releases/tag/${version}";
+    license = licenses.mit;
+    maintainers = with maintainers; [ fab ];
+    mainProgram = "route-graph";
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/ro/roxterm/package.nix b/nixpkgs/pkgs/by-name/ro/roxterm/package.nix
index 8a978e98b6d4..8b4f2e79c2be 100644
--- a/nixpkgs/pkgs/by-name/ro/roxterm/package.nix
+++ b/nixpkgs/pkgs/by-name/ro/roxterm/package.nix
@@ -31,13 +31,13 @@
 
 stdenv.mkDerivation (finalAttrs: {
   pname = "roxterm";
-  version = "3.15.0";
+  version = "3.14.3";
 
   src = fetchFromGitHub {
     owner = "realh";
     repo = "roxterm";
     rev = finalAttrs.version;
-    hash = "sha256-mmfnpZTCsLJ4EPxsKZXeHBZnpvc2n1TCEPmiIHmnxKc=";
+    hash = "sha256-NSOGq3rN+9X4WA8Q0gMbZ9spO/dbZkzeo4zEno/Kgcs=";
   };
 
   nativeBuildInputs = [