Merge branch 'nixos-unstable-small' of https://github.com/NixOS/nixpkgs

1 files changed, 53 insertions, 0 deletions

diff --git a/nixpkgs/pkgs/by-name/mi/miru/package.nix b/nixpkgs/pkgs/by-name/mi/miru/package.nix
new file mode 100644
index 000000000000..467b5a5260d9
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mi/miru/package.nix
@@ -0,0 +1,53 @@
+{ lib
+, fetchurl
+, appimageTools
+}:
+
+appimageTools.wrapType2 rec {
+  pname = "miru";
+  version = "4.5.10";
+
+  src = fetchurl {
+    url = "https://github.com/ThaUnknown/miru/releases/download/v${version}/linux-Miru-${version}.AppImage";
+    name = "${pname}-${version}.AppImage";
+    sha256 = "sha256-ptaviLwr0X/MuF517YLW7i9+rtnktcpgHVqMHn+tXWg=";
+  };
+
+  extraInstallCommands =
+    let
+      contents = appimageTools.extractType2 { inherit pname version src; };
+    in
+    ''
+      mkdir -p "$out/share/applications"
+      mkdir -p "$out/share/lib/miru"
+      cp -r ${contents}/{locales,resources} "$out/share/lib/miru"
+      cp -r ${contents}/usr/* "$out"
+      cp "${contents}/${pname}.desktop" "$out/share/applications/"
+      mv "$out/bin/${pname}-${version}" "$out/bin/${pname}"
+      substituteInPlace $out/share/applications/${pname}.desktop --replace 'Exec=AppRun' 'Exec=${pname}'
+    '';
+
+  meta = with lib; {
+    description = "Stream anime torrents, real-time with no waiting for downloads";
+    homepage = "https://github.com/ThaUnknown/miru#readme";
+    license = licenses.gpl3Plus;
+    maintainers = [ maintainers.d4ilyrun ];
+    mainProgram = "miru";
+
+    platforms = [ "x86_64-linux" ];
+    sourceProvenance = [ lib.sourceTypes.binaryNativeCode ];
+
+    longDescription = ''
+      A pure JS BitTorrent streaming environment, with a built-in list manager.
+      Imagine qBit + Taiga + MPV, all in a single package, but streamed real-time.
+      Completely ad free with no tracking/data collection.
+
+      This app is meant to feel look, work and perform like a streaming website/app,
+      while providing all the advantages of torrenting, like file downloads,
+      higher download speeds, better video quality and quicker releases.
+
+      Unlike qBit's sequential, seeking into undownloaded data will prioritise downloading that data,
+      instead of flat out closing MPV.
+    '';
+  };
+}