Merge branch 'nixos-unstable-small' of https://github.com/NixOS/nixpkgs into HEAD

3 files changed, 145 insertions, 0 deletions

diff --git a/nixpkgs/pkgs/by-name/me/memtree/package.nix b/nixpkgs/pkgs/by-name/me/memtree/package.nix
new file mode 100644
index 000000000000..2165b46e2b48
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/me/memtree/package.nix
@@ -0,0 +1,50 @@
+{ lib
+, fetchFromGitHub
+, nix-update-script
+, python3Packages
+}:
+
+python3Packages.buildPythonApplication {
+  pname = "memtree";
+  version = "unstable-2023-11-04";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "nbraud";
+    repo = "memtree";
+    rev = "093caeef26ee944b5bf4408710f63494e442b5ff";
+    hash = "sha256-j4LqWy7DxeV7pjwnCfpkHwug4p48kux6BM6oDJmvuUo=";
+  };
+
+  nativeBuildInputs = with python3Packages; [
+    poetry-core
+  ];
+
+  propagatedBuildInputs = with python3Packages; [
+    rich
+  ];
+
+  nativeCheckInputs = with python3Packages; [
+    hypothesis
+    pytest
+  ];
+
+  checkPhase = ''
+    runHook preCheck
+    python -m pytest -v
+    runHook postCheck
+  '';
+
+  pythonImportChecks = [ "memtree" ];
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [ "--version=branch" ];
+  };
+
+  meta = with lib; {
+    description = "Render cgroups tree annotated by memory usage";
+    homepage = "https://github.com/nbraud/memtree";
+    maintainers = with maintainers; [ nicoo ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/me/mercure/package.nix b/nixpkgs/pkgs/by-name/me/mercure/package.nix
new file mode 100644
index 000000000000..e90bd8d10ba4
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/me/mercure/package.nix
@@ -0,0 +1,53 @@
+{ lib
+, buildGoModule
+, fetchFromGitHub
+, nix-update-script
+, testers
+, mercure
+}:
+
+buildGoModule rec {
+  pname = "mercure";
+  version = "0.15.5";
+
+  src = fetchFromGitHub {
+    owner = "dunglas";
+    repo = "mercure";
+    rev = "v${version}";
+    hash = "sha256-DyKNKhxjnOfxYcp3w1nB6kxs9c4ZaHL0AN0Eb5vc6mA=";
+  };
+
+  sourceRoot = "source/caddy";
+
+  vendorHash = "sha256-2SZv6iwEZjq/50WwwupfHjbg0vNpff/Cn21nPqeHJMw=";
+
+  subPackages = [ "mercure" ];
+  excludedPackages = [ "../cmd/mercure" ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X 'github.com/caddyserver/caddy/v2.CustomVersion=Mercure.rocks v${version} Caddy'"
+  ];
+
+  doCheck = false;
+
+  passthru = {
+    updateScript = nix-update-script { };
+    tests.version = testers.testVersion {
+      version = "v${version}";
+      package = mercure;
+      command = "mercure version";
+    };
+  };
+
+  meta = with lib; {
+    description = "An open, easy, fast, reliable and battery-efficient solution for real-time communications";
+    homepage = "https://github.com/dunglas/mercure";
+    changelog = "https://github.com/dunglas/mercure/releases/tag/v${version}";
+    license = licenses.agpl3Only;
+    maintainers = with maintainers; [ gaelreyrol ];
+    platforms = platforms.unix;
+    mainProgram = "mercure";
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/me/meritous/package.nix b/nixpkgs/pkgs/by-name/me/meritous/package.nix
new file mode 100644
index 000000000000..8b0a176938aa
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/me/meritous/package.nix
@@ -0,0 +1,42 @@
+{ lib, stdenv, fetchFromGitLab, SDL, SDL_image, SDL_mixer, zlib }:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "meritous";
+  version = "1.5";
+
+  src = fetchFromGitLab {
+    owner = "meritous";
+    repo = "meritous";
+    rev = "refs/tags/v${finalAttrs.version}";
+    hash = "sha256-6KK2anjX+fPsYf4HSOHQ0EQBINqZiVbxo1RmBR6pslg=";
+  };
+
+  prePatch = ''
+    substituteInPlace Makefile \
+      --replace "prefix=/usr/local" "prefix=$out" \
+      --replace sdl-config ${lib.getDev SDL}/bin/sdl-config
+
+    substituteInPlace src/audio.c \
+      --replace "filename[64]" "filename[256]"
+  '';
+
+  buildInputs = [ SDL SDL_image SDL_mixer zlib ];
+
+  installPhase = ''
+    install -m 555 -D meritous $out/bin/meritous
+    mkdir -p $out/share/meritous
+    cp -r dat/* $out/share/meritous/
+  '';
+
+  hardeningDisable = [ "stackprotector" "fortify" ];
+
+  meta = with lib; {
+    description = "Action-adventure dungeon crawl game";
+    homepage = "https://gitlab.com/meritous/meritous";
+    changelog = "https://gitlab.com/meritous/meritous/-/blob/master/NEWS";
+    license = licenses.gpl3Only;
+    mainProgram = "meritous";
+    maintainers = [ maintainers.alexvorobiev ];
+    platforms = platforms.linux;
+  };
+})