Merge remote-tracking branch 'nixpkgs/nixos-unstable-small'

Conflicts:
	nixpkgs/nixos/modules/services/mail/mailman.nix
	nixpkgs/nixos/modules/services/mail/public-inbox.nix
	nixpkgs/pkgs/build-support/go/module.nix

5 files changed, 314 insertions, 2 deletions

diff --git a/nixpkgs/pkgs/by-name/dm/dmarc-report-converter/package.nix b/nixpkgs/pkgs/by-name/dm/dmarc-report-converter/package.nix
index 5fff732e84fc..488ce0a92d64 100644
--- a/nixpkgs/pkgs/by-name/dm/dmarc-report-converter/package.nix
+++ b/nixpkgs/pkgs/by-name/dm/dmarc-report-converter/package.nix
@@ -7,13 +7,13 @@
 
 buildGoModule rec {
   pname = "dmarc-report-converter";
-  version = "0.7.1";
+  version = "0.7.2";
 
   src = fetchFromGitHub {
     owner = "tierpod";
     repo = "dmarc-report-converter";
     rev = "v${version}";
-    hash = "sha256-cP96tiBpMFNEHuIF0sovi+Q4yW8wMUqr138RyMOFoho=";
+    hash = "sha256-93sNEBV7MxZr6tqPaFKgY0KA1J3W0HoCiIDZg268Smc=";
   };
 
   vendorHash = null;
diff --git a/nixpkgs/pkgs/by-name/dm/dmd/binary.nix b/nixpkgs/pkgs/by-name/dm/dmd/binary.nix
new file mode 100644
index 000000000000..3a5d6b76cec8
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/dm/dmd/binary.nix
@@ -0,0 +1,77 @@
+{ lib, stdenv, fetchurl, curl, tzdata, autoPatchelfHook, fixDarwinDylibNames, glibc
+, version, hashes }:
+
+let
+  inherit (stdenv) hostPlatform;
+  OS = if hostPlatform.isDarwin then "osx" else hostPlatform.parsed.kernel.name;
+  MODEL = toString hostPlatform.parsed.cpu.bits;
+in
+
+# On linux pargets like `pkgsLLVM.dmd` `cc` does not expose `libgcc`
+# and can't build `dmd`.
+assert hostPlatform.isLinux -> (stdenv.cc.cc ? libgcc);
+stdenv.mkDerivation {
+  pname = "dmd-bootstrap";
+  inherit version;
+
+  src = fetchurl rec {
+    name = "dmd.${version}.${OS}.tar.xz";
+    url = "http://downloads.dlang.org/releases/2.x/${version}/${name}";
+    sha256 = hashes.${OS} or (throw "missing bootstrap sha256 for OS ${OS}");
+  };
+
+  dontConfigure = true;
+  dontBuild = true;
+
+  nativeBuildInputs = lib.optionals hostPlatform.isLinux [
+    autoPatchelfHook
+  ] ++ lib.optionals hostPlatform.isDarwin [
+    fixDarwinDylibNames
+  ];
+  propagatedBuildInputs = [
+    curl
+    tzdata
+  ] ++ lib.optionals hostPlatform.isLinux [
+    glibc
+    stdenv.cc.cc.libgcc
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out
+
+    # try to copy model-specific binaries into bin first
+    mv ${OS}/bin${MODEL} $out/bin || true
+
+    mv src license.txt ${OS}/* $out/
+
+    # move man into place
+    mkdir -p $out/share
+    mv man $out/share/
+
+    # move docs into place
+    mkdir -p $out/share/doc
+    mv html/d $out/share/doc/
+
+    # fix paths in dmd.conf (one level less)
+    substituteInPlace $out/bin/dmd.conf --replace "/../../" "/../"
+
+    runHook postInstall
+  '';
+
+  # Stripping on Darwin started to break libphobos2.a
+  # Undefined symbols for architecture x86_64:
+  #   "_rt_envvars_enabled", referenced from:
+  #       __D2rt6config16rt_envvarsOptionFNbNiAyaMDFNbNiQkZQnZQq in libphobos2.a(config_99a_6c3.o)
+  dontStrip = hostPlatform.isDarwin;
+
+  meta = with lib; {
+    description = "Digital Mars D Compiler Package";
+    # As of 2.075 all sources and binaries use the boost license
+    license = licenses.boost;
+    maintainers = [ maintainers.lionello ];
+    homepage = "https://dlang.org/";
+    platforms = [ "x86_64-darwin" "i686-linux" "x86_64-linux" ];
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/dm/dmd/bootstrap.nix b/nixpkgs/pkgs/by-name/dm/dmd/bootstrap.nix
new file mode 100644
index 000000000000..16aa5ed4d404
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/dm/dmd/bootstrap.nix
@@ -0,0 +1,9 @@
+{ callPackage }:
+callPackage ./binary.nix {
+  version = "2.090.1";
+  hashes = {
+    # Get these from `nix-prefetch-url http://downloads.dlang.org/releases/2.x/2.090.1/dmd.2.090.1.linux.tar.xz` etc..
+    osx = "sha256-9HwGVO/8jfZ6aTiDIUi8w4C4Ukry0uUS8ACP3Ig8dmU=";
+    linux = "sha256-ByCrIA4Nt7i9YT0L19VXIL1IqIp+iObcZux407amZu4=";
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/dm/dmd/generic.nix b/nixpkgs/pkgs/by-name/dm/dmd/generic.nix
new file mode 100644
index 000000000000..9bfd2c5ffc9f
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/dm/dmd/generic.nix
@@ -0,0 +1,221 @@
+{ version
+, dmdHash
+, phobosHash
+}:
+
+{ stdenv
+, lib
+, fetchFromGitHub
+, removeReferencesTo
+, makeWrapper
+, which
+, writeTextFile
+, curl
+, tzdata
+, gdb
+, Foundation
+, callPackage
+, targetPackages
+, fetchpatch
+, bash
+, installShellFiles
+, git
+, unzip
+, dmdBootstrap ? callPackage ./bootstrap.nix { }
+, dmdBin ? "${dmdBootstrap}/bin"
+}:
+
+let
+  dmdConfFile = writeTextFile {
+    name = "dmd.conf";
+    text = (lib.generators.toINI { } {
+      Environment = {
+        DFLAGS = ''-I@out@/include/dmd -L-L@out@/lib -fPIC ${lib.optionalString (!targetPackages.stdenv.cc.isClang) "-L--export-dynamic"}'';
+      };
+    });
+  };
+
+  bits = builtins.toString stdenv.hostPlatform.parsed.cpu.bits;
+  osname =
+    if stdenv.isDarwin then
+      "osx"
+    else
+      stdenv.hostPlatform.parsed.kernel.name;
+
+  pathToDmd = "\${NIX_BUILD_TOP}/dmd/generated/${osname}/release/${bits}/dmd";
+in
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "dmd";
+  inherit version;
+
+  enableParallelBuilding = true;
+
+  srcs = [
+    (fetchFromGitHub {
+      owner = "dlang";
+      repo = "dmd";
+      rev = "v${finalAttrs.version}";
+      hash = dmdHash;
+      name = "dmd";
+    })
+    (fetchFromGitHub {
+      owner = "dlang";
+      repo = "phobos";
+      rev = "v${finalAttrs.version}";
+      hash = phobosHash;
+      name = "phobos";
+    })
+  ];
+
+  sourceRoot = ".";
+
+  # https://issues.dlang.org/show_bug.cgi?id=19553
+  hardeningDisable = [ "fortify" ];
+
+  patches = lib.optionals (lib.versionOlder version "2.088.0") [
+    # Migrates D1-style operator overloads in DMD source, to allow building with
+    # a newer DMD
+    (fetchpatch {
+      url = "https://github.com/dlang/dmd/commit/c4d33e5eb46c123761ac501e8c52f33850483a8a.patch";
+      stripLen = 1;
+      extraPrefix = "dmd/";
+      hash = "sha256-N21mAPfaTo+zGCip4njejasraV5IsWVqlGR5eOdFZZE=";
+    })
+  ];
+
+  postPatch = ''
+    patchShebangs dmd/compiler/test/{runnable,fail_compilation,compilable,tools}{,/extra-files}/*.sh
+
+    rm dmd/compiler/test/runnable/gdb1.d
+    rm dmd/compiler/test/runnable/gdb10311.d
+    rm dmd/compiler/test/runnable/gdb14225.d
+    rm dmd/compiler/test/runnable/gdb14276.d
+    rm dmd/compiler/test/runnable/gdb14313.d
+    rm dmd/compiler/test/runnable/gdb14330.d
+    rm dmd/compiler/test/runnable/gdb15729.sh
+    rm dmd/compiler/test/runnable/gdb4149.d
+    rm dmd/compiler/test/runnable/gdb4181.d
+    rm dmd/compiler/test/compilable/ddocYear.d
+
+    # Disable tests that rely on objdump whitespace until fixed upstream:
+    #   https://issues.dlang.org/show_bug.cgi?id=23317
+    rm dmd/compiler/test/runnable/cdvecfill.sh
+    rm dmd/compiler/test/compilable/cdcmp.d
+  '' + lib.optionalString (lib.versionAtLeast version "2.089.0" && lib.versionOlder version "2.092.2") ''
+    rm dmd/compiler/test/dshell/test6952.d
+  '' + lib.optionalString (lib.versionAtLeast version "2.092.2") ''
+    substituteInPlace dmd/compiler/test/dshell/test6952.d --replace-fail "/usr/bin/env bash" "${bash}/bin/bash"
+  '' + lib.optionalString stdenv.isLinux ''
+    substituteInPlace phobos/std/socket.d --replace-fail "assert(ih.addrList[0] == 0x7F_00_00_01);" ""
+  '' + lib.optionalString stdenv.isDarwin ''
+    substituteInPlace phobos/std/socket.d --replace-fail "foreach (name; names)" "names = []; foreach (name; names)"
+  '';
+
+  nativeBuildInputs = [
+    makeWrapper
+    which
+    installShellFiles
+  ] ++ lib.optionals (lib.versionOlder version "2.088.0") [
+    git
+  ];
+
+  buildInputs = [
+    curl
+    tzdata
+  ] ++ lib.optionals stdenv.isDarwin [
+    Foundation
+  ];
+
+  nativeCheckInputs = [
+    gdb
+  ] ++ lib.optionals (lib.versionOlder version "2.089.0") [
+    unzip
+  ];
+
+  buildFlags = [
+    "BUILD=release"
+    "ENABLE_RELEASE=1"
+    "PIC=1"
+  ];
+
+  # Build and install are based on http://wiki.dlang.org/Building_DMD
+  buildPhase = ''
+    runHook preBuild
+
+    export buildJobs=$NIX_BUILD_CORES
+    [ -z "$enableParallelBuilding" ] && buildJobs=1
+
+    ${dmdBin}/rdmd dmd/compiler/src/build.d -j$buildJobs $buildFlags \
+      HOST_DMD=${dmdBin}/dmd
+    make -C dmd/druntime -j$buildJobs DMD=${pathToDmd} $buildFlags
+    echo ${tzdata}/share/zoneinfo/ > TZDatabaseDirFile
+    echo ${lib.getLib curl}/lib/libcurl${stdenv.hostPlatform.extensions.sharedLibrary} \
+      > LibcurlPathFile
+    make -C phobos -j$buildJobs $buildFlags \
+      DMD=${pathToDmd} DFLAGS="-version=TZDatabaseDir -version=LibcurlPath -J$PWD"
+
+    runHook postBuild
+  '';
+
+  doCheck = true;
+
+  # many tests are disabled because they are failing
+
+  # NOTE: Purity check is disabled for checkPhase because it doesn't fare well
+  # with the DMD linker. See https://github.com/NixOS/nixpkgs/issues/97420
+  checkPhase = ''
+    runHook preCheck
+
+    export checkJobs=$NIX_BUILD_CORES
+    [ -z "$enableParallelChecking" ] && checkJobs=1
+
+    CC=$CXX HOST_DMD=${pathToDmd} NIX_ENFORCE_PURITY= \
+      ${dmdBin}/rdmd dmd/compiler/test/run.d -j$checkJobs
+
+    NIX_ENFORCE_PURITY= \
+      make -C phobos unittest -j$checkJobs $checkFlags \
+        DFLAGS="-version=TZDatabaseDir -version=LibcurlPath -J$PWD"
+
+    runHook postCheck
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 ${pathToDmd} $out/bin/dmd
+
+    installManPage dmd/docs/man/man*/*
+
+    mkdir -p $out/include/dmd
+    cp -r {dmd/druntime/import/*,phobos/{std,etc}} $out/include/dmd/
+
+    mkdir $out/lib
+    cp phobos/generated/${osname}/release/${bits}/libphobos2.* $out/lib/
+
+    wrapProgram $out/bin/dmd \
+      --prefix PATH : "${targetPackages.stdenv.cc}/bin" \
+      --set-default CC "${targetPackages.stdenv.cc}/bin/cc"
+
+    substitute ${dmdConfFile} "$out/bin/dmd.conf" --subst-var out
+
+    runHook postInstall
+  '';
+
+  preFixup = ''
+    find $out/bin -type f -exec ${removeReferencesTo}/bin/remove-references-to -t ${dmdBin}/dmd '{}' +
+  '';
+
+  disallowedReferences = [ dmdBootstrap ];
+
+  meta = with lib; {
+    description = "Official reference compiler for the D language";
+    homepage = "https://dlang.org/";
+    # Everything is now Boost licensed, even the backend.
+    # https://github.com/dlang/dmd/pull/6680
+    license = licenses.boost;
+    mainProgram = "dmd";
+    maintainers = with maintainers; [ lionello dukc jtbx ];
+    platforms = [ "x86_64-linux" "i686-linux" "x86_64-darwin" ];
+  };
+})
diff --git a/nixpkgs/pkgs/by-name/dm/dmd/package.nix b/nixpkgs/pkgs/by-name/dm/dmd/package.nix
new file mode 100644
index 000000000000..9f3f5a26e7e5
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/dm/dmd/package.nix
@@ -0,0 +1,5 @@
+import ./generic.nix {
+  version = "2.108.0";
+  dmdHash = "sha256-tlWcFgKtXzfqMMkOq4ezhZHdYCXFckjN5+m6jO4VH0U=";
+  phobosHash = "sha256-uU8S4rABOfhpKh+MvSbclkbdf0hrsuKF8SIpWMnPpfU=";
+}