sshd: Add support for socket activation

By enabling ‘services.openssh.startWhenNeeded’, sshd is started
on-demand by systemd using socket activation. This is particularly
useful if you have a zillion containers and don't want to have sshd
running permanently. Note that socket activation is not noticeable
slower, contrary to what the manpage for ‘sshd -i’ says, so we might
want to make this the default one day.

1 files changed, 58 insertions, 25 deletions

diff --git a/nixos/modules/services/networking/ssh/sshd.nix b/nixos/modules/services/networking/ssh/sshd.nix
index d666b462d157..554cc6a1c3fc 100644
--- a/nixos/modules/services/networking/ssh/sshd.nix
+++ b/nixos/modules/services/networking/ssh/sshd.nix
@@ -86,6 +86,16 @@ in
         '';
       };
 
+      startWhenNeeded = mkOption {
+        type = types.bool;
+        default = false;
+        description = ''
+          If set, <command>sshd</command> is socket-activated; that
+          is, instead of having it permanently running as a daemon,
+          systemd will start an instance for each incoming connection.
+        '';
+      };
+
       forwardX11 = mkOption {
         type = types.bool;
         default = cfgc.setXAuthLocation;
@@ -248,37 +258,60 @@ in
       }
     ];
 
-    systemd.services.sshd =
-      { description = "SSH Daemon";
-
-        wantedBy = [ "multi-user.target" ];
+    systemd =
+      let
+        service =
+          { description = "SSH Daemon";
+
+            wantedBy = optional (!cfg.startWhenNeeded) "multi-user.target";
+
+            stopIfChanged = false;
+
+            path = [ pkgs.openssh pkgs.gawk ];
+
+            environment.LD_LIBRARY_PATH = nssModulesPath;
+
+            preStart =
+              ''
+                mkdir -m 0755 -p /etc/ssh
+
+                ${flip concatMapStrings cfg.hostKeys (k: ''
+                  if ! [ -f "${k.path}" ]; then
+                      ssh-keygen -t "${k.type}" -b "${toString k.bits}" -f "${k.path}" -N ""
+                  fi
+                '')}
+              '';
+
+            serviceConfig =
+              { ExecStart =
+                  "${pkgs.openssh}/sbin/sshd " + (optionalString cfg.startWhenNeeded "-i ") +
+                  "-f ${pkgs.writeText "sshd_config" cfg.extraConfig}";
+                KillMode = "process";
+              } // (if cfg.startWhenNeeded then {
+                StandardInput = "socket";
+              } else {
+                Restart = "always";
+                Type = "forking";
+                PIDFile = "/run/sshd.pid";
+              });
+          };
+      in
 
-        stopIfChanged = false;
+      if cfg.startWhenNeeded then {
 
-        path = [ pkgs.openssh pkgs.gawk ];
+        sockets.sshd =
+          { description = "SSH Socket";
+            wantedBy = [ "sockets.target" ];
+            socketConfig.ListenStream = cfg.ports;
+            socketConfig.Accept = true;
+          };
 
-        environment.LD_LIBRARY_PATH = nssModulesPath;
+        services."sshd@" = service;
 
-        preStart =
-          ''
-            mkdir -m 0755 -p /etc/ssh
+      } else {
 
-            ${flip concatMapStrings cfg.hostKeys (k: ''
-              if ! [ -f "${k.path}" ]; then
-                  ssh-keygen -t "${k.type}" -b "${toString k.bits}" -f "${k.path}" -N ""
-              fi
-            '')}
-          '';
+        services.sshd = service;
 
-        serviceConfig =
-          { ExecStart =
-              "${pkgs.openssh}/sbin/sshd " +
-              "-f ${pkgs.writeText "sshd_config" cfg.extraConfig}";
-            Restart = "always";
-            Type = "forking";
-            KillMode = "process";
-            PIDFile = "/run/sshd.pid";
-          };
       };
 
     networking.firewall.allowedTCPPorts = cfg.ports;