socklog: init at 2.1.0

2 files changed, 55 insertions, 0 deletions

diff --git a/pkgs/tools/system/socklog/default.nix b/pkgs/tools/system/socklog/default.nix
new file mode 100644
index 000000000000..e0adad4eff85
--- /dev/null
+++ b/pkgs/tools/system/socklog/default.nix
@@ -0,0 +1,53 @@
+{ stdenv, fetchurl }:
+
+with stdenv.lib;
+
+stdenv.mkDerivation rec {
+  name = "socklog-${version}";
+  version = "2.1.0";
+
+  src = fetchurl {
+    url = "http://smarden.org/socklog/socklog-${version}.tar.gz";
+    sha256 = "0mdlmhiq2j2fip7c4l669ams85yc3c1s1d89am7dl170grw9m1ma";
+  };
+
+  sourceRoot = "admin/socklog-${version}";
+
+  outputs = [ "out" "man" "doc" ];
+
+  configurePhase = ''
+    echo "$NIX_CC/bin/cc $NIX_CFLAGS_COMPILE"   >src/conf-cc
+    echo "$NIX_CC/bin/cc -s"                    >src/conf-ld
+  '';
+
+  buildPhase = ''package/compile'';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    mv command"/"* $out/bin
+
+    for i in {1,8} ; do
+      mkdir -p $man/share/man/man$i
+      mv man"/"*.$i $man/share/man/man$i
+    done
+
+    mkdir -p $doc/share/socklog/html
+    mv doc"/"*.html $doc/share/socklog/html/
+
+    runHook postInstall
+  '';
+
+  checkPhase = ''package/check'';
+
+  doCheck = true;
+
+  meta = {
+    description = "System and kernel logging services";
+    homepage = http://smarden.org/socklog/;
+    license = licenses.publicDomain;
+    platforms = platforms.unix;
+    maintainers = [ maintainers.joachifm ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 7796ae6c6a53..725e304ef0dc 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -1026,6 +1026,8 @@ with pkgs;
 
   playerctl = callPackage ../tools/audio/playerctl { };
 
+  socklog = callPackage ../tools/system/socklog { };
+
   syscall_limiter = callPackage ../os-specific/linux/syscall_limiter {};
 
   syslogng = callPackage ../tools/system/syslog-ng { };