blob: 5c8427679c82d066c2d8afd7f1dc5bd7aac02b15 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
{ lib, stdenv
, buildPackages
, fetchFromGitHub
, rustPlatform
, installShellFiles
, pkg-config
, Security
, withPCRE2 ? true
, pcre2
, enableManpages ? stdenv.hostPlatform.emulatorAvailable buildPackages
}:
rustPlatform.buildRustPackage rec {
pname = "ripgrep";
version = "14.0.3";
src = fetchFromGitHub {
owner = "BurntSushi";
repo = pname;
rev = version;
hash = "sha256-NBGbiy+1AUIBJFx6kcGPSKo08a+dkNo4rNH2I1pki4U=";
};
cargoHash = "sha256-s6oK0/eL+NAhG3ySUlJBRatUuWXxfRVgAvlJm++0lkg=";
nativeBuildInputs = [ installShellFiles ]
++ lib.optional withPCRE2 pkg-config;
buildInputs = lib.optional withPCRE2 pcre2
++ lib.optional stdenv.isDarwin Security;
buildFeatures = lib.optional withPCRE2 "pcre2";
preFixup = lib.optionalString enableManpages ''
${stdenv.hostPlatform.emulator buildPackages} $out/bin/rg --generate man > rg.1
installManPage rg.1
'' + ''
installShellCompletion --cmd rg \
--bash <($out/bin/rg --generate complete-bash) \
--fish <($out/bin/rg --generate complete-fish) \
--zsh <($out/bin/rg --generate complete-zsh)
'';
doInstallCheck = true;
installCheckPhase = ''
file="$(mktemp)"
echo "abc\nbcd\ncde" > "$file"
$out/bin/rg -N 'bcd' "$file"
$out/bin/rg -N 'cd' "$file"
'' + lib.optionalString withPCRE2 ''
echo '(a(aa)aa)' | $out/bin/rg -P '\((a*|(?R))*\)'
'';
meta = with lib; {
description = "A utility that combines the usability of The Silver Searcher with the raw speed of grep";
homepage = "https://github.com/BurntSushi/ripgrep";
changelog = "https://github.com/BurntSushi/ripgrep/releases/tag/${version}";
license = with licenses; [ unlicense /* or */ mit ];
maintainers = with maintainers; [ globin ma27 zowoq ];
mainProgram = "rg";
};
}
|