blob: bf324c57d497aab8bf95b721dff735f360fc5700 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
{ stdenv
, lib
, fetchFromGitHub
, autoreconfHook
, pkg-config
, libcap
, ncurses
, jansson
, withGtk ? false
, gtk3
}:
stdenv.mkDerivation rec {
pname = "mtr${lib.optionalString withGtk "-gui"}";
version = "0.95";
src = fetchFromGitHub {
owner = "traviscross";
repo = "mtr";
rev = "v${version}";
sha256 = "sha256-f5bL3IdXibIc1xXCuZHwcEV5vhypRE2mLsS3A8HW2QM=";
};
# we need this before autoreconfHook does its thing
postPatch = ''
echo ${version} > .tarball-version
'';
# and this after autoreconfHook has generated Makefile.in
preConfigure = ''
substituteInPlace Makefile.in \
--replace ' install-exec-hook' ""
'';
configureFlags = lib.optional (!withGtk) "--without-gtk";
nativeBuildInputs = [ autoreconfHook pkg-config ];
buildInputs = [ ncurses jansson ]
++ lib.optional withGtk gtk3
++ lib.optional stdenv.isLinux libcap;
enableParallelBuilding = true;
meta = with lib; {
description = "A network diagnostics tool";
homepage = "https://www.bitwizard.nl/mtr/";
license = licenses.gpl2;
maintainers = with maintainers; [ koral orivej raskin globin ];
platforms = platforms.unix;
};
}
|