blob: af98ed1ae1b73f11265d7c0931ec72c223b97072 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
{ stdenv, lib, fetchurl
, autoreconfHook, libtool, pkg-config
, gtk2, glib, cups, gettext, openssl
}:
stdenv.mkDerivation rec {
pname = "gtklp";
version = "1.3.4";
src = fetchurl {
url = "mirror://sourceforge/${pname}/${pname}-${version}.src.tar.gz";
sha256 = "1arvnnvar22ipgnzqqq8xh0kkwyf71q2sfsf0crajpsr8a8601xy";
};
nativeBuildInputs = [
pkg-config
autoreconfHook
];
buildInputs = [
cups
gettext
glib
gtk2
libtool
openssl
];
patches = [
./patches/mdv-fix-str-fmt.patch
./patches/autoconf.patch
];
# Workaround build failure on -fno-common toolchains:
# ld: libgtklp.a(libgtklp.o):libgtklp/libgtklp.h:83: multiple definition of `progressBar';
# file.o:libgtklp/libgtklp.h:83: first defined here
env.NIX_CFLAGS_COMPILE = "-fcommon";
preConfigure = ''
substituteInPlace include/defaults.h --replace "netscape" "firefox"
substituteInPlace include/defaults.h --replace "http://localhost:631/sum.html#STANDARD_OPTIONS" \
"http://localhost:631/help/"
'';
preInstall = ''
install -D -m0644 -t $out/share/doc AUTHORS BUGS ChangeLog README USAGE
'';
meta = with lib; {
description = "A graphical frontend for CUPS";
homepage = "https://gtklp.sirtobi.com";
license = licenses.gpl2Only;
maintainers = with maintainers; [ caadar ];
platforms = platforms.unix;
};
}
|