blob: a33a55d63e7ddf8a34e204f8c5ba027df7b919b6 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
{ ffmpeg_6-full
, nv-codec-headers-12
, chromaprint
, fetchFromGitHub
, lib
}:
(ffmpeg_6-full.override {
nv-codec-headers-11 = nv-codec-headers-12;
}).overrideAttrs (old: rec {
pname = "jellyfin-ffmpeg";
version = "6.0-7";
src = fetchFromGitHub {
owner = "jellyfin";
repo = "jellyfin-ffmpeg";
rev = "v${version}";
sha256 = "sha256-Z4getn/mVYIRANkIOyt7jMpcqHBvq5GXLK/ST5zV1r4=";
};
buildInputs = old.buildInputs ++ [ chromaprint ];
configureFlags = old.configureFlags ++ [
"--extra-version=Jellyfin"
"--disable-ptx-compression" # https://github.com/jellyfin/jellyfin/issues/7944#issuecomment-1156880067
"--enable-chromaprint"
];
postPatch = ''
for file in $(cat debian/patches/series); do
patch -p1 < debian/patches/$file
done
${old.postPatch or ""}
'';
meta = with lib; {
description = "${old.meta.description} (Jellyfin fork)";
homepage = "https://github.com/jellyfin/jellyfin-ffmpeg";
license = licenses.gpl3;
maintainers = with maintainers; [ justinas ];
pkgConfigModules = [ "libavutil" ];
};
})
|