nixpkgs/nixos/modules/services/system/zram-generator.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

{ config, lib, pkgs, ... }:
let
  cfg = config.services.zram-generator;
  settingsFormat = pkgs.formats.ini { };
in
{
  meta = {
    maintainers = with lib.maintainers; [ nickcao ];
  };

  options.services.zram-generator = {
    enable = lib.mkEnableOption (lib.mdDoc "Systemd unit generator for zram devices");

    package = lib.mkPackageOption pkgs "zram-generator" { };

    settings = lib.mkOption {
      type = lib.types.submodule {
        freeformType = settingsFormat.type;
      };
      default = { };
      description = lib.mdDoc ''
        Configuration for zram-generator,
        see https://github.com/systemd/zram-generator for documentation.
      '';
    };
  };

  config = lib.mkIf cfg.enable {
    system.requiredKernelConfig = with config.lib.kernelConfig; [
      (isModule "ZRAM")
    ];

    systemd.packages = [ cfg.package ];
    systemd.services."systemd-zram-setup@".path = [ pkgs.util-linux ]; # for mkswap

    environment.etc."systemd/zram-generator.conf".source = settingsFormat.generate "zram-generator.conf" cfg.settings;
  };
}