blob: 5ce198a08611d3ac689d301e6de8f3bd0ee8b0ac (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# SPDX-FileCopyrightText: 2021-2022 Alyssa Ross <hi@alyssa.is>
# SPDX-License-Identifier: MIT
{ pkgs ? import <nixpkgs> {}
, rootfs ? import ../rootfs { inherit pkgs; }
}:
pkgs.callPackage (
{ lib, stdenv, runCommand, writeReferencesToFile, pkgsStatic
, busybox, cpio, cryptsetup, lvm2
}:
let
inherit (lib) cleanSource cleanSourceWith concatMapStringsSep;
linux = rootfs.kernel;
packages = [
pkgsStatic.execline pkgsStatic.kmod pkgsStatic.mdevd
(pkgsStatic.cryptsetup.override {
programs = {
cryptsetup = false;
cryptsetup-reencrypt = false;
integritysetup = false;
};
})
(busybox.override {
enableStatic = true;
extraConfig = ''
CONFIG_DEPMOD n
CONFIG_FINDFS n
CONFIG_INSMOD n
CONFIG_LSMOD n
CONFIG_MODINFO n
CONFIG_MODPROBE n
CONFIG_RMMOD n
'';
})
];
packagesSysroot = runCommand "packages-sysroot" {} ''
mkdir -p $out/bin
ln -s ${concatMapStringsSep " " (p: "${p}/bin/*") packages} $out/bin
cp -R ${linux}/lib $out
ln -s /bin $out/sbin
# TODO: this is a hack and we should just build the util-linux
# programs we want.
# https://lore.kernel.org/util-linux/87zgrl6ufb.fsf@alyssa.is/
cp ${pkgsStatic.util-linuxMinimal}/bin/{findfs,lsblk} $out/bin
'';
packagesCpio = runCommand "packages.cpio" {
nativeBuildInputs = [ cpio ];
storePaths = writeReferencesToFile packagesSysroot;
} ''
cd ${packagesSysroot}
(printf "/nix\n/nix/store\n" && find . $(< $storePaths)) |
cpio -o -H newc -R +0:+0 --reproducible > $out
'';
in
stdenv.mkDerivation {
name = "initramfs";
src = cleanSourceWith {
filter = name: _type: name != "${toString ./.}/build";
src = cleanSource ./.;
};
PACKAGES_CPIO = packagesCpio;
nativeBuildInputs = [ cpio ];
installPhase = ''
runHook preInstall
cp build/initramfs $out
runHook postInstall
'';
enableParallelBuilding = true;
}
) {}
|