host/initramfs: move to monorepo path

1 files changed, 66 insertions, 0 deletions

diff --git a/host/initramfs/default.nix b/host/initramfs/default.nix
new file mode 100644
index 0000000..ba6ede2
--- /dev/null
+++ b/host/initramfs/default.nix
@@ -0,0 +1,66 @@
+{ pkgs ? import <nixpkgs> {} }: pkgs.callPackage (
+
+{ lib, stdenv, runCommand, writeReferencesToFile, pkgsStatic
+, busybox, cpio, cryptsetup, linux, lvm2
+}:
+
+let
+  cryptsetup' = cryptsetup;
+in
+let
+  inherit (lib) cleanSource cleanSourceWith concatMapStringsSep;
+
+  cryptsetup = cryptsetup'.override { lvm2 = lvm2.override { udev = null; }; };
+
+  packages = [
+    cryptsetup pkgsStatic.mdevd pkgsStatic.execline
+
+    (busybox.override {
+      enableStatic = true;
+      extraConfig = ''
+        CONFIG_FINDFS n
+      '';
+    })
+  ];
+
+  packagesSysroot = runCommand "packages-sysroot" {} ''
+    mkdir -p $out/bin
+    ln -s ${concatMapStringsSep " " (p: "${p}/bin/*") packages} $out/bin
+    cp -R ${linux}/lib $out
+    ln -s /bin $out/sbin
+
+    # TODO: this is a hack and we should just build the util-linux
+    # programs we want.
+    # https://lore.kernel.org/util-linux/87zgrl6ufb.fsf@alyssa.is/
+    cp ${pkgsStatic.util-linux.override { systemd = null; }}/bin/{findfs,lsblk} $out/bin
+  '';
+
+  packagesCpio = runCommand "packages.cpio" {
+    nativeBuildInputs = [ cpio ];
+    storePaths = writeReferencesToFile packagesSysroot;
+  } ''
+    cd ${packagesSysroot}
+    (printf "/nix\n/nix/store\n" && find . $(< $storePaths)) |
+        cpio -o -H newc -R +0:+0 --reproducible > $out
+  '';
+in
+
+stdenv.mkDerivation {
+  name = "initramfs";
+
+  src = cleanSourceWith {
+    filter = name: _type: name != "${toString ./.}/build" && name != "${toString ./.}/spectrum-live";
+    src = cleanSource ./.;
+  };
+
+  PACKAGES_CPIO = packagesCpio;
+
+  nativeBuildInputs = [ cpio ];
+
+  installPhase = ''
+    cp build/initramfs $out
+  '';
+
+  enableParallelBuilding = true;
+}
+) {}